home *** CD-ROM | disk | FTP | other *** search
/ Internet Info 1994 March / Internet Info CD-ROM (Walnut Creek) (March 1994).iso / networking / terms / kermit / a / mssker.asm < prev    next >
Encoding:
Assembly Source File  |  1993-07-12  |  78.7 KB  |  2,596 lines
  1.     NAME    mssker
  2. ; File MSSKER.ASM
  3.     include mssdef.h
  4. ; Edit history:
  5. ; 8 July 1993 version 3.13
  6. ; 6 Sept 1991 version 3.11
  7. ; Last edit 8 July 1993
  8. ;****************************** Version 3.10 ***************************** 
  9. ; KERMIT, Celtic for "free" 
  10. ;
  11. ; The name "Kermit" is a registered trade mark of Henson Associates, Inc.,
  12. ; used by permission.
  13. ;
  14. ;    MS-DOS Kermit Program Version 3.13, 8 July 93
  15. ;    MS-DOS Kermit Program Version 3.12, Feb 1992
  16. ;    MS-DOS Kermit Program Version 3.11, 6 Sept 1991
  17. ;    MS-DOS Kermit Program Version 3.10, 2 March 1991
  18. ;    MS-DOS Kermit Program Version 3.02, development for 3.10, 1990-91
  19. ;    MS-DOS Kermit Program Version 3.01, 20 March 1990
  20. ;    MS-DOS Kermit Program Version 3.00, 16 Jan 1990 
  21. ;    Kermit-MS Program Version 2.32, 11 Dec 1988 
  22. ;    Kermit-MS Program Version 2.31, 1 July 1988
  23. ;       Kermit-MS Program Version 2.30, 1 Jan 1988
  24. ;    Kermit-MS Program Version 2.29, 26 May 1986, plus later revisions.
  25. ;       Kermit-MS Program Version 2.27, December 6,1984
  26. ;       Kermit-MS Program Version 2.26, July 27, 1984
  27. ;       PC-Kermit Program Version 1.20, November 4, 1983
  28. ;       PC-Kermit Program Version 1.0, 1982
  29. ; 
  30. ;       Based on the Columbia University KERMIT Protocol.
  31. ; 
  32. ;  Copyright (C) 1985, 1993, Trustees of Columbia University in the 
  33. ;  City of New York.  Permission is granted to any individual or institution
  34. ;  to use this software as long as it is not sold for profit.  This copyright
  35. ;  notice must be retained.  This software may not be included in commercial
  36. ;  products without written permission of Columbia University.
  37. ;
  38. ;       Original Authors (versions 1.0 through 2.28):
  39. ;         Daphne Tzoar, Jeff Damens
  40. ;         Columbia University Center for Computing Activities
  41. ;         612 West 115th Street
  42. ;         New York, NY  10025
  43. ;
  44. ;       Present author (version 2.29, 2.30, 2.31, 2.32, 3.00, 3.01, 3.02,
  45. ;            3.10, 3.11, 3.12):
  46. ;         Joe R. Doupnik
  47. ;      Dept of EE, and CASS
  48. ;      Utah State University
  49. ;      Logan, UT  84322, USA
  50. ;      E-Mail: JRD@CC.USU.EDU (Internet), JRD@USU (BITNET)
  51. ; 
  52. ; Special thanks to Christine Gianone, Frank da Cruz, Bill Catchings, 
  53. ; Bernie Eiben, Vace Kundakci, Terry Kennedy, Jack Bryans, and many many
  54. ; others for their help and contributions.
  55.  
  56.     public    dosnum, curdsk, fpush, isfile, sbrk, crun, errlev
  57.     public    takrd, takadr, taklev, filtst, maxtry, dskspace, thsep, tdfmt
  58.     public    lclsusp, lclrest, lclexit, cwdir, kstatus, verident, cdsr
  59.     public    spath, patched, oldtak, getenv, psp, dosctty, patchid
  60.     public    tcptos, emsrbhandle, emsgshandle, apctrap
  61.  
  62. env    equ    2CH            ; environment address in psp
  63. cline    equ    80H            ; offset in psp of command line
  64. braceop    equ    7bh            ; opening curly brace
  65. bracecl    equ    7dh            ; closing curly brace
  66.  
  67. _STACK    SEGMENT                ; our stack
  68.     dw    1500 dup (0)        ; for TCP code
  69.     dw    200 dup(0)        ; for main Kermit code
  70. msfinal    label    word            ; top of stack
  71. _STACK    ENDS
  72.  
  73. data   segment
  74.     extrn    buff:byte, comand:byte, flags:byte, trans:byte,    prmptr:word
  75.     extrn    machnam:byte, decbuf:byte, rstate:byte, sstate:byte
  76.     extrn    mcctab:byte, rdbuf:byte
  77.  
  78. verident label    byte
  79.     verdef
  80. patchena db    '$patch level'
  81. patchid    db    ' 0 $'
  82. copyright db    cr,lf
  83.     db    'Copyright (C) Trustees of Columbia University 1982, 1993.'
  84.     db    cr,lf,'$'
  85. hlpmsg    db     cr,lf,'Type ? or HELP for help',cr,lf,'$'
  86. crlf    db      cr,lf,'$'
  87. ermes1    db    cr,lf,'?More parameters are needed$'
  88. ermes2    db    cr,lf,'?Unable to initialize memory$'
  89. ermes3  db      cr,lf,'?Command canceled$'
  90. ermes4    db    '?Unable to change directory',0            ; asciiz
  91. ermes5    db    cr,lf,'?Unable to complete initialization process$'
  92. ermes6    db    cr,lf,'Ignoring patch file.'
  93.     db    ' Version number mismatch.',cr,lf,'$'
  94. ermes7    db    cr,lf,'Patch file was not found',cr,lf,'$'
  95. ermes8    db    cr,lf,'Fatal error in patch file! Please remove PATCH '
  96.     db    'command.',cr,lf,'$'
  97. erms30    db    cr,lf,'?Passed maximum nesting level for TAKE command$'
  98. erms31    db    cr,lf,'?Cannot find Take-file: $'
  99. erms34    db    cr,lf,'This program requires DOS 2.0 or above$'
  100. erms37    db    cr,lf,'?Unable to execute command interpreter $'
  101. badnam    db    cr,lf,'?No such file(s)$'
  102. filmsg    db    ' Filename$'
  103. dskmsg    db    ' disk drive letter or Return$'
  104. pthmsg    db    ' Name of new working directory and/or disk$'
  105. runmsg    db    ' program name and command line$'
  106. pathlp    db    ' optional path for file mskermit.pch$'
  107. stophlp    db    'Status value to be returned  msg, nothing if no new value$'
  108. tophlp    db    cr,lf
  109.     db    '  Ask, Askq (read keybd to variable) '
  110.     db    '  Open Read/Write/Append file  scripts'
  111.     db    cr,lf
  112.     db    '  Bye      (logout remote server)    '
  113.     db    '  Output text     (for scripts)'
  114.     db    cr,lf
  115.     db      '  C or Connect  (become a terminal)  '
  116.     db    '  Pause [seconds], MPause [millisec]'
  117.     db    cr,lf
  118.     db    '  Clear   (Input, comms recv buffer) '
  119.     db    '  Pop, End (exit current macro/Take file)'
  120.     db    cr,lf
  121.     db    '  Close    (logging and script file) '
  122.     db    '  Push     (go to DOS, keep Kermit)'
  123.     db    cr,lf
  124.     db    '  CLS (clear screen at command level)'
  125.         db      '  Quit     (leave Kermit)'
  126.     db    cr,lf
  127.     db    '  CWD or CD  (change dir &/or disk)  '
  128.         db      '  R or Receive  (opt local filename)'
  129.     db    cr,lf
  130.     db    '  Decrement/Increment variable number'
  131.     db    '  Read (line from a file to variable)'
  132.     db    cr,lf
  133.     db    '  Define/Assign   (a command macro)  '
  134.     db    '  Reinput  (script Input, reread buffer)'
  135.     db    cr,lf
  136.     db    '  Delete   (a file)                  '
  137.     db    '  Remote   (prefix for commands)'
  138.     db    cr,lf
  139.     db    '  Directory (filepsec)               '
  140.     db    '  Replay   (file through term emulator)'
  141.     db    cr,lf
  142.     db    '  Disable  (selected server commands)'
  143.     db    '  Run      (a program)'
  144.     db    cr,lf
  145.     db    '  Echo text (show line on screen)    '
  146.         db      '  S or Send  local file   new name'
  147.     db    cr,lf         
  148.     db    '  Enable   (selected server commands)'
  149.     db    '  Server [timeout] (become a server)'
  150.     db    cr,lf
  151.     db      '  EXIT     (leave Kermit)            '
  152.         db      '  Set      (most things)'
  153.     db    cr,lf
  154.     db    '  Finish   (to remote server)        '
  155.     db    '  Show     (most things)'
  156.     db    cr,lf
  157.     db    '  Get      (remote file opt new name)'
  158.     db    '  Space    (free on current disk)'
  159.     db    cr,lf
  160.     db    '  GetOK    (get Yes, OK, No response)'
  161.     db    '  Stop     (exit all Take files & macros)'
  162.     db    cr,lf
  163.     db    '  Goto    (label, Take file or Macro)'
  164.     db    '  Take     (do a command file)'
  165.     db    cr,lf
  166.     db    '  Hangup   (drop DTR, hang up phone) '
  167.     db    '  Transmit filespec [prompt] (raw upload)'
  168.     db    cr,lf
  169.     db    '  If [not] <condition> <command>     '
  170.     db    '  Type     (a file)'
  171.     db    cr,lf
  172.     db    '  I or Input [timeout] text (scripts)'
  173.     db    '  Wait [timeout] on modem \cd \cts \dsr'
  174.     db    cr,lf
  175.     db    '  Log (Packet, Session, Transaction) '
  176.     db    '  Write  FILE or log file   text'
  177.     db    cr,lf
  178.     db    '  Mail     (file to host Mailer)     '
  179.     db    '$'
  180. data    ends
  181.  
  182. data1    segment
  183. qckhlp    db cr,lf
  184.     db '                    Introduction to MS-DOS Kermit',cr,lf
  185.     db 'o An MS-Kermit command is a line of words separated by spaces and'
  186.     db ' ending with',cr,lf,'  a carriage return <the Enter key>.'
  187.     db '  Example: SET SPEED 2400<Enter>',cr,lf
  188.     db 'o Most words can be abbreviated and can be completed by pressing'
  189.     db ' the Esc key.',cr,lf
  190.     db '  Example: SET SPE 24<Enter>  or even  SET SPE<Esc> 24<Esc>'
  191.     db '<Enter>',cr,lf
  192.     db 'o Help (detailed, specific): press the "?" key where a word would'
  193.     db ' appear.',cr,lf
  194.     db 'o Edit lines using the Backspace key to delete characters,'
  195.     db ' Control-W to delete',cr,lf
  196.     db '  words, and Control-U to delete the line.  Control-C cancels the'
  197.     db ' command.',cr,lf
  198.     db 'o Frequently used MS-Kermit commands:',cr,lf
  199.     db '  EXIT           Leave the Kermit program. QUIT does the same'
  200.     db ' thing.',cr,lf
  201.     db '  SET            PORT, PARITY, SPEED, TERMINAL and many other'
  202.     db ' parameters.',cr,lf
  203.     db '  SHOW or STATUS Display groups of important parameters.'
  204.     db ' SHOW ? for categories.',cr,lf,lf
  205.     db '  CONNECT        Establish a terminal connection to a remote'
  206.     db ' system or a modem.',cr,lf
  207.     db '  Control-$'
  208. qckhlp1    db ' C    (Control-$'
  209. qckhlp2    db '  followed by "C")  Return to MS-Kermit> prompt.',cr,lf,lf
  210.     db '  SEND filename  Send the file(s) to Kermit on the other'
  211.     db ' computer.',cr,lf
  212.     db '  RECEIVE        Receive file(s), SEND them from Kermit on the'
  213.     db ' other computer.',cr,lf
  214.     db '  GET filename   Ask the remote Kermit server to send the file(s)'
  215.     db ' to us.',cr,lf
  216.     db '  FINISH         Shut down remote Kermit but stay logged into'
  217.     db ' remote system.',cr,lf
  218.     db '  BYE            FINISH and logout of remote system and exit'
  219.     db ' local Kermit.',cr,lf
  220.     db 'o Common startup sequence: SET SPEED 9600, CONNECT, login, start'
  221.     db ' remote Kermit,',cr,lf
  222.     db '  put it into Server mode, escape back with Control-$'
  223. qckhlp3    db ' C, transfer'
  224.     db ' files with',cr,lf
  225.     db '  SEND x.txt, GET b.txt, BYE.'
  226.     db cr,lf
  227.     db ' - more -  Press the space bar for more information$'
  228. qckhlp4 db cr,lf
  229.     db ' DOCUMENTATION'
  230.     db cr,lf,lf
  231.     db ' MS-DOS Kermit is fully documentated in:'
  232.     db cr,lf, ' Christine M. Gianone, "Using MS-DOS Kermit", Second'
  233.     db ' Edition,'
  234.     db cr,lf,'   Digital Press, Bedford, MA, 1992, 345 pages:'
  235.     db cr,lf,' USA Order Number: EY-H893E-DP'
  236.     db cr,lf,' USA Digital Press ISBN: 1-55558-082-3'
  237.     db cr,lf,' USA Prentice Hall ISBN: 0-13-952276-X'
  238.     db cr,lf,' International Edition Order Number: EY-H893E-DI'
  239.     db cr,lf,' International Prentice Hall ISBN: 0-13-953043-6'
  240.     db cr,lf,' Available in computer bookstores or directly from Digital'
  241.     db ' Press.'
  242.     db cr,lf,' In the USA, call Digital Press toll-free 1-800-344-4825'
  243.     db ' to order;'
  244.     db cr,lf,'   major credit cards accepted. Overseas, order through'
  245.     db ' your bookstore or'
  246.     db cr,lf,'   your local Digital Equipment Corporation branch.'
  247.     db cr,lf,lf,' For additional information, contact:'
  248.     db cr,lf,'   Kermit Development and Distribution'
  249.     db cr,lf,'   Columbia University Academic Information Systems'
  250.     db cr,lf,'   612 West 115th Street'
  251.     db cr,lf,'   New York, NY  10025  USA'
  252.     db cr,lf,'   Telephone: (USA) 212 854-3703'
  253.     db cr,lf
  254.     db cr,lf,' New features are documented in KERMIT.UPD (MSKERM.UPD)'
  255.     db cr,lf,' For hints and tips, please read KERMIT.BWR (MSKERM.BWR)'
  256.     db cr,lf,' - more -  Press the space bar for a functional summary'
  257.     db ' of Kermit commands. $'
  258.  
  259. qckhlp5    db    cr,lf,lf,lf,lf,lf,lf,lf
  260.     db ' MS-DOS Kermit commands, a functional summary:'
  261.     db    cr,lf
  262.     db    cr,lf,' Local file management:         '
  263.     db    'Kermit program management:'
  264.     db    cr,lf,'   DIR    (list files)          '
  265.     db    '  EXIT     (from Kermit, return to DOS)'
  266.     db    cr,lf,'   CD     (change directory)    '
  267.     db    '  QUIT     (same as EXIT)'
  268.     db    cr,lf,'   DELETE (delete files)        '      
  269.     db    '  TAKE     (execute Kermit commands from file)'
  270.     db    cr,lf,'   RUN    (a DOS command)       '
  271.     db    '  CLS      (clear screen)'
  272.     db    cr,lf,'   TYPE   (display a file)      '
  273.     db    '  PUSH     (enter DOS, EXIT returns to Kermit)'
  274.     db    cr,lf,'   SPACE  (show disk space)     '
  275.     db    '  Ctrl-C   (interrupt a command)'
  276.     db    cr,lf
  277.     db    cr,lf,' Communication settings:        '
  278.     db    'Terminal emulation:'
  279.     db    cr,lf,'   SET PORT, SET SPEED          '
  280.     db    '  CONNECT  (begin terminal emulation)'
  281.     db    cr,lf,'   SET PARITY                   '
  282.     db    '  HANGUP   (close connection)'
  283.     db    cr,lf,'   SET FLOW-CONTROL             '
  284.     db    '  Alt-X    (return to MS-Kermit> prompt)'
  285.     db    cr,lf,'   SET LOCAL-ECHO               '
  286.     db    '  SET KEY  (key mapping)'
  287.     db    cr,lf,'   SET ? to see others          '
  288.     db    '  SET TERMINAL TYPE, BYTESIZE, other parameters'
  289.     db    cr,lf,'   SHOW COMMUNICATIONS, MODEM   '
  290.     db    '  SHOW TERMINAL, SHOW KEY'
  291.     db    cr,lf,lf,' - more -$'
  292. qckhlp6    db    cr,'          '
  293.     db    cr,lf,' File transfer settings:        '
  294.     db    cr,lf,'   SET FILE CHARACTER-SET name  '  
  295.     db    '  SET TRANSFER CHARACTER-SET'
  296.     db    cr,lf,'   SET FILE TYPE TEXT, BINARY   '  
  297.     db    '  SET SEND or RECEIVE parameters'
  298.     db    cr,lf,'   SET FILE ? to see others     '  
  299.     db    '  SET WINDOWS (sliding windows)'
  300.     db    cr,lf,'   SHOW FILE                    '  
  301.     db    '  SHOW PROTOCOL, SHOW STATISTICS'
  302.     db    cr,lf
  303.     db    cr,lf,' Kermit file transfer:           '
  304.     db    'ASCII file transfer:'
  305.     db    cr,lf,'   SEND files (to RECEIVE)      '
  306.     db    '  LOG SESSION, CLOSE SESSION (download)'
  307.     db    cr,lf,'   RECEIVE    (from SEND)       '
  308.     db    '  TRANSMIT (upload)'
  309.     db    cr,lf,'   MAIL files (to RECEIVE)      '
  310.     db    '  SET TRANSMIT parameters'
  311.     db    cr,lf,lf,' - more - $'
  312. qckhlp7    db    cr,'          '
  313.     db    cr,lf,' Using a Kermit server:         '
  314.     db    'Being a kermit server:'
  315.     db    cr,lf,'   GET files    (from server)   '
  316.     db    '  SET SERVER TIMEOUT or LOGIN'
  317.     db    cr,lf,'   SEND or MAIL   (to server)   '
  318.     db    '  ENABLE or DISABLE features'
  319.     db    cr,lf,'   REMOTE command (to server)   '
  320.     db    '  SERVER'
  321.     db    cr,lf,'   FINISH, LOGOUT, BYE          '
  322.     db    '  SHOW SERVER'
  323.     db    cr,lf
  324.     db    cr,lf,' Script programming commands:   '
  325.     db    cr,lf,'   INPUT, REINPUT secs text     '
  326.     db    '  :label, GOTO label'
  327.     db    cr,lf,'   OUTPUT text                  '
  328.     db    '  IF [ NOT ] condition command'
  329.     db    cr,lf,'   DECREMENT or INCREMENT variable number'
  330.     db    cr,lf,'   ASK or ASKQ variable prompt  '
  331.     db    '  OPEN READ (or WRITE or APPEND) file'
  332.     db    cr,lf,'   DEFINE variable or macro     '
  333.     db    '  READ variable-name'
  334.     db    cr,lf,'   ASSIGN variable or macro     '
  335.     db    '  WRITE file-designator text'
  336.     db    cr,lf,'   [ DO ] macro arguments       '
  337.     db    '  CLOSE READ or WRITE file or logfile'
  338.     db    cr,lf,'   ECHO text                    '
  339.     db    '  END or POP from macro or file'
  340.     db    cr,lf,'   PAUSE time                   '
  341.     db    '  STOP all macros and command files'
  342.     db    cr,lf,'   WAIT time modem-signals      '
  343.     db    '  WRITE file-designator text'
  344.     db    cr,lf,'   SHOW SCRIPTS, SHOW MACROS    '
  345.     db    '  SHOW VARIABLES'
  346.     db    cr,lf,lf
  347.     db ' Use "?" within comands for help on what fits that word.',lf,'$'
  348. kpath    db    65 dup (0)        ; Kermit's path to Kermit files
  349. data1    ends
  350.  
  351. data    segment
  352.  
  353. comtab  db    71            ; COMND tables
  354.     mkeyw    'Asg',assign        ; synonym
  355.     mkeyw    'Ask',ask
  356.     mkeyw    'Askq',askq
  357.     mkeyw    'Assign',assign
  358.     mkeyw    'Bye',bye
  359.     mkeyw    'C',telnet
  360.     mkeyw    'CD',cwdir
  361.     mkeyw    'Clear',scclr
  362.     mkeyw    'Close',clscpt
  363.     mkeyw    'Comment',comnt
  364.     mkeyw    'Connect',telnet
  365.     mkeyw    'CLS',cls
  366.     mkeyw    'CWD',cwdir
  367.     mkeyw    'Define',dodef
  368.     mkeyw    'Decrement',decvar
  369.     mkeyw    'Delete',delete
  370.     mkeyw    'Directory',direct
  371.     mkeyw    'Disable',srvdsa
  372.     mkeyw    'Do',docom
  373.     mkeyw    'Echo',scecho
  374.     mkeyw    'Enable',srvena
  375.     mkeyw    'End',popcmd
  376.     mkeyw    'Exit',exit
  377.     mkeyw    'Finish',finish
  378.     mkeyw    'Get',get
  379.     mkeyw    'G',get            ; hidden synomym for Get
  380.     mkeyw    'Ge',get        ; ditto
  381.     mkeyw    'Getok',getok
  382.     mkeyw    'goto',sgoto
  383.     mkeyw    'H',help
  384.     mkeyw    'Hangup',dtrlow
  385.     mkeyw    'Help',help
  386.     mkeyw    'If',ifcmd
  387.     mkeyw    'I',scinp
  388.     mkeyw    'Increment',incvar
  389.     mkeyw    'Input',scinp
  390. ;;;    mkeyw    'Load',load
  391.     mkeyw    'Log',setcpt
  392.     mkeyw    'Mail',mail
  393.     mkeyw    'Mpause',scmpause
  394.     mkeyw    'Open',vfopen
  395.     mkeyw    'O',scout        ; hidden synomym for OUTPUT
  396.     mkeyw    'Output',scout
  397.     mkeyw    'Pause',scpau
  398.     mkeyw    'Pop',popcmd
  399.     mkeyw    'Push',dopush
  400.     mkeyw    'Quit',exit
  401.     mkeyw    'R',read
  402.     mkeyw    'Read',vfread
  403.     mkeyw    'Receive',read
  404.     mkeyw    'Reinput',screinp
  405.     mkeyw    'Remote',remote
  406.     mkeyw    'Replay',replay
  407.     mkeyw    'Run',run
  408.     mkeyw    'S',send
  409.     mkeyw    'Send',send
  410.     mkeyw    'Server',server
  411.     mkeyw    'Set',setcom
  412.     mkeyw    'Show',showcmd
  413.     mkeyw    'Space',chkdsk
  414.     mkeyw    'Statistics',shosta
  415.     mkeyw    'Stay',stay
  416.     mkeyw    'Stop',takeqit
  417.     mkeyw    'Take',take
  418.     mkeyw    'Transmit',scxmit
  419.     mkeyw    'xmit',scxmit        ; hidden synonym
  420.     mkeyw    'Type',typec
  421.     mkeyw    'Version',prvers
  422.     mkeyw    'Wait',scwait
  423.     mkeyw    'Write',write
  424.     mkeyw    ':',comnt        ; script labels, do not react
  425.     mkeyw    'Patch',patch
  426.  
  427. shotab    db    17            ; SHOW keyword
  428.     mkeyw    'Communications',shcom
  429.     mkeyw    'Control-prefixing',cntlsho
  430.     mkeyw    'File',shfile
  431.     mkeyw    'Key',shokey
  432.     mkeyw    'Logging',shlog
  433.     mkeyw    'Macros',shomac
  434.     mkeyw    'Memory',shmem
  435.     mkeyw    'Modem',shomodem
  436.     mkeyw    'Protocol',shpro
  437.     mkeyw    'Scripts',shscpt
  438.     mkeyw    'Server',shserv
  439.     mkeyw    'Sessions',sesdisp    ; TCP/IP
  440.     mkeyw    'Statistics',shosta
  441.     mkeyw    'Status',status
  442.     mkeyw    'Terminal',shterm
  443.     mkeyw    'Translation',shorx
  444.     mkeyw    'Variables',shovar
  445.                     ; Kermit initing from Environment
  446. nulprmpt db    0            ; null prompt
  447. initab    db    8            ; Environment phrase dispatch table
  448.     mkeyw    'INPUT-buffer-length',setinpbuf ; Script INPUT buffer length
  449.     mkeyw    'Rollback',setrollb    ; number of Terminal rollback screens
  450.     mkeyw    'Width',setwidth    ; columns in rollback buffer, def=80
  451.     mkeyw    'COM1',com1port
  452.     mkeyw    'COM2',com2port
  453.     mkeyw    'COM3',com3port
  454.     mkeyw    'COM4',com4port
  455.     mkeyw    'Path',mkkpath
  456.  
  457. patched    db    1        ; 1 = enable patching; 0 = disable or done
  458.  
  459.     even
  460. lclsusp    dw    0        ; address of routine to call when going to DOS
  461. lclrest    dw    0        ; address of routine to call when returning
  462. lclexit    dw    0        ; address of routine to call when exiting
  463. tcptos    dw    0        ; top of stack for TCP code
  464. ssave    dd    0        ; Original SS:SP when doing Command.com
  465. in3ad    dw    0,0        ; Original break interrupt addresses
  466. ceadr    dd    0        ; DOS Critical Error interrupt address
  467. orgcbrk    db    0        ; original Control-Break Check state
  468. psp    dw    0        ; segment of Program Segment Prefix
  469. exearg    dw    0        ; segment addr of environment (filled in below)
  470.     dd    0        ; ptr to cmd line (filled in below)
  471.     dw    5ch,0,6ch,0    ; our def fcb's; segment filled in later
  472. emsrbhandle dw    -1        ; EMS rollback handle, -1 means invalid
  473. emsgshandle dw    -1        ; EMS graphics handle, -1 means invalid
  474. dosnum    dw    0        ; dos version number, major=low, minor=high
  475. dosctty    db    0        ; !=0 if DOS attempts using our comms line
  476. curdsk    db    0        ; Current disk
  477. origd    db    0        ; Original disk
  478. orgdir    db    64 dup (0)    ; original directory on original disk
  479. taklev    db    0        ; Take levels
  480. oldtak    db    0        ; Take level at start of command parse
  481. takadr    dw    takstr-(size takinfo) ; Pointer into structure
  482. takstr    db    (size takinfo) * maxtak dup(?)
  483. cmdlinetake db    0        ; non-zero if have DOS command line cmds
  484. filtst    filest    <>        ; file structure for procedure isfile
  485. maxtry    db    defmxtry    ; Retry limit for data packet send/rcv
  486. ininm2    db    'MSKERMIT.INI',0 ; init file name
  487. ptchnam    db    'MSR313.PCH',0    ; main patch file name (Version dependent)
  488. ptchnam2 db    'MSKERMIT.PCH',0 ; alternate patch file name
  489. delcmd    db    ' del ',0    ; delete command
  490. dircmd    db    ' dir ',0    ; directory command
  491. typcmd    db    ' type ',0    ; type command
  492. kerenv    db    'KERMIT=',0,0    ; Kermit= environment variable, + 2 nulls
  493. pthnam    db    'PATH='        ; Path environment variable
  494. pthlen    equ    $-pthnam    ;  length of that string
  495. pthadr    dw    0        ; offset of PATH= string
  496.  
  497. slashc    db    ' /c '        ; slashc Must directly preceed tmpbuf
  498. tmpbuf    db    128 dup (0)    ; temp space for file names and comments
  499. cmspnam    db    'COMSPEC='    ; Environment variable
  500. cmsplen    equ    $-cmspnam
  501. cmspbuf    db    '\command.com',30 dup (0) ; default name plus additional space
  502. shellnam db    'SHELL='    ; Environment variable
  503. shellen    equ    $-shellnam
  504. shellbuf db    40 dup (0)    ; buffer for name
  505. eexit    db    cr,'exit',cr
  506. leexit    equ    $-eexit
  507. onexit    db    7,0,'ON_EXIT'    ; <length>on_exit macro name
  508. onexlen    equ    $-onexit-2    ; length of name
  509. mfmsg    db    '?Not enough memory to run Kermit$'
  510. mf7msg    db    '?Attempted to allocate a corrupted memory area$'
  511. spcmsg    db    ' bytes available on drive '
  512. spcmsg1    db    ' :',cr,lf,0
  513. spcmsg2    db    cr,lf,' Drive '
  514. spcmsg3    db    ' : is not ready',0
  515. errlev    db    0        ; DOS errorlevel to be returned
  516. kstatus    dw    0        ; command execution status (0 = success)
  517. thsep    db    0        ; thousands separator
  518. tdfmt    db    0        ; date/time format code
  519. totpar    dw    0
  520. apctrap    db    0        ; disable command if done via APC
  521. temp    dw    0
  522.  
  523. segstr    db    'ABCDEFG'    ; segment "names" for patcher
  524. lsegstr    equ    $-segstr
  525.     even
  526. segtab    dw    code        ; segment values for patcher
  527.     dw    code1
  528.     dw    code2
  529.     dw    data
  530.     dw    data1
  531.     dw    _TEXT
  532.     dw    dgroup
  533. data   ends
  534.  
  535. code    segment
  536.     extrn    mail:near, load:near, shovar:near
  537.     extrn    bye:near, telnet:near, finish:near, comnd:near, prompt:near
  538.     extrn    read:near, remote:near, send:near, status:near, get:near
  539.     extrn    serrst:near, setcom:near, dtrlow:near, cmblnk:near
  540.     extrn    clscpi:near, clscpt:near, scpini:near, setrollb:near
  541.     extrn    dodef:near, setcpt:near, docom:near, shomodem:near
  542.     extrn    server:near, lclini:near, shokey:near, shomac:near, shosta:near
  543.     extrn    strlen:near, strcpy:near, shserv:near, initibm:near
  544.     extrn    strcat:near, prtasz:near, shorx:near, lnout:near, lnouts:near
  545.     extrn    scout:near,scinp:near,scpau:near,scecho:near,scclr:near
  546.     extrn    scxmit:near, scwait:near, srvdsa:near, srvena:near
  547.     extrn    shcom:near, shlog:near, shpro:near, shterm:near, shscpt:near
  548.     extrn    shfile:near, takopen:near, takclos:near, ask:near, askq:near
  549.     extrn    assign:near, sgoto:near, screinp:near, ifcmd:near, write:near
  550.     extrn    setinpbuf:near, shmem:near, replay:near, atoi:near
  551.     extrn    katoi:near, com1port:near, com2port:near, com3port:near
  552.     extrn    com4port:near, popcmd:near, mprompt:near, locate:near
  553.     extrn    vfopen:near, vfread:near, decvar:near, incvar:near
  554.     extrn    fparse:near, setwidth:near, cnvlin:near, scmpause:near
  555.     extrn    sesdisp:near, getok:near, cntlsho:near
  556.  
  557.         assume  cs:code, ds:data, ss:_stack, es:nothing
  558.  
  559. START    PROC    FAR
  560.     mov    ax,data            ; initialize DS
  561.         mov    ds,ax
  562.     mov    psp,es            ; remember psp address
  563.     mov    ah,dosver        ; get DOS version number (word)
  564.     int    dos
  565.     xchg    ah,al            ; major version to ah
  566.     mov    dosnum,ax        ; remember dos version
  567.     cmp    ax,200h            ; earlier than DOS 2.0?
  568.     jge    start1            ; ge = no
  569.     mov    ah,prstr
  570.     mov    dx,offset erms34    ; complain
  571.     int    dos
  572.     push    psp            ; set up exit for DOS 1
  573.     xor    ax,ax            ; and the IP
  574.     push    ax            ; make return addr of psp:0 for DOS 1
  575.     ret                ; and return far to exit now
  576. start1:
  577.     call    memini            ; initialize our memory usage
  578.     mov    ah,setdma        ; set disk transfer address
  579.     mov    dx,offset buff
  580.     int    dos
  581.     call    far ptr setint        ; ^C, DOS critical error interrupts
  582.     mov    ah,gcurdsk        ; get current disk
  583.     int    dos
  584.     inc    al            ; make 1 == A (not zero)
  585.     mov    curdsk,al
  586.     mov    origd,al        ; remember original disk we started on
  587.     mov    si,offset orgdir     ; place for directory path w/o drive code
  588.     add    al,'A'-1        ; make al alphabetic disk drive again
  589.     mov    [si],al            ; put it into original path descriptor
  590.     inc    si
  591.     mov    byte ptr [si],':'    ; add drive specifier too
  592.     inc    si
  593.     mov    byte ptr [si],'\'    ; add root indicator as well
  594.     inc    si
  595.     mov    ah,gcd            ; get current directory (path really)
  596.     xor    dl,dl            ; use current drive
  597.     int    dos
  598.     call    getpath            ; get the path from the environment
  599.     call    gettsep            ; get thousands separator, t/date code
  600.     mov    ah,gswitch
  601.     xor    al,al            ; pick up switch character
  602.     int    dos
  603.     mov    slashc+1,dl
  604.     and    maxtry,3fh        ; limit # packet retries
  605.     call    getcsp            ; get comspec from environment
  606.     call    getssp            ; get shellspec from environment
  607.     call    getparm            ; read "KERMIT=" Environment line
  608.     jc    start1b            ; c = fatal error
  609.     xor    cl,cl            ; counter, starts at 0
  610. start1a:mov    bx,offset kerenv+6    ; append "<digit>="  to "KERMIT"
  611.     mov    [bx],cl            ; binary digit
  612.     inc    cl
  613.     add    byte ptr [bx],'0'    ; to ascii
  614.     mov    byte ptr [bx+1],'='    ; append equals sign
  615.     call    getparm            ; read "KERMITn=" Environment line
  616.     jc    start1b            ; c = fatal error
  617.     cmp    cl,9            ; done all digits?
  618.     jbe    start1a            ; be = no
  619.                     ;
  620.     call    scpini            ; initialize script routines
  621.     jc    start1b            ; c = fatal error
  622.     call    lclini            ; do local initialization
  623.     cmp    flags.extflg,0        ; exit now?
  624.     je    start2            ; e = no
  625. start1b:mov    ah,prstr        ; announce our premature exit
  626.     mov    dx,offset ermes5    ; can't complete initialization
  627.     int    dos
  628.     jmp    krmend            ; quit immediately
  629. start2:    mov    word ptr comand.cmrprs,offset krmend ; offset of reparse addr
  630.     mov    ax,cs            ; our current code segment
  631.     mov    word ptr comand.cmrprs+2,ax ; segment of reparse address
  632.     mov    comand.cmostp,sp    ; save for reparse too
  633.     call    gcmdlin            ; read command line
  634.     cmp    taklev,0        ; in a Take file?
  635.     jne    start3            ; ne = yes, skip help msg
  636.     mov    ah,prstr
  637.     mov    dx,offset machnam    ; display machine name
  638.     int    dos
  639.         mov    dx,offset verident    ; display version header
  640.         int    dos
  641.     mov    dx,offset copyright    ; display copyright notice
  642.     int    dos
  643.     mov    dx,offset hlpmsg
  644.     int    dos
  645. start3:    mov    patchena,' '        ; let patch level show
  646.     call    serrst            ; reset serial port (if active)
  647.     call    initibm            ; define IBM macro
  648.     call    rdinit            ; read kermit init file
  649.  
  650.  ; This is the main KERMIT loop.  It prompts for and gets the users commands
  651.  
  652. kermit:    mov    ax,ds
  653.     mov    es,ax            ; convenient safety measure
  654.     mov    dx,prmptr        ; get prompt string address
  655.     call    mprompt              ; set master reparse address to here
  656.     cmp    flags.cxzflg,'C'    ; did someone want out?
  657.     jne    kermt9            ; ne = no
  658. kermt8:    cmp    taklev,0        ; are we in a Take file?
  659.     je    kermt9            ; e = no, ignore the signal
  660.     call    takclos            ; close take file, release buffer
  661.     jmp    short kermt8        ; close any other take files
  662. kermt9:    mov    flags.cxzflg,0        ; reset each time
  663.     and    flags.remflg,not dserver ; turn off server mode bit
  664.     cmp    dosctty,0        ; is DOS using our comms line?
  665.     je    kermt1            ; e = no
  666.     and    flags.remflg,not(dquiet+dregular+dserial)
  667.     or    flags.remflg,dquiet    ; set display to quiet mode
  668.     call    serrst            ; close port so CTTY can run
  669. kermt1:    mov    dx,offset comtab
  670.     mov    bx,offset tophlp
  671.     cmp    flags.extflg,0        ; exit flag set?
  672.     jne    krmend            ; ne = yes, jump to KRMEND
  673.     mov    comand.cmcr,1        ; allow bare CR's
  674.         mov    ah,cmkey
  675.     mov    comand.impdo,1        ; allow implied "DO macro"
  676.     call    comnd
  677.     jc    kermt3            ; c = failure
  678.     mov    comand.impdo,0        ; only on initial keyword, not here
  679.     mov    comand.cmcr,0        ; no more bare CR's
  680.     call    bx                  ; call the routine returned in BX
  681.     jc    kermt3            ; c = failure
  682.     cmp    flags.extflg,0        ; exit flag set?
  683.     jne    krmend            ; ne = yes, jump to KRMEND
  684.     jmp    short kermt5        ; do idle loop cleanup
  685.  
  686. kermt3:    cmp    flags.cxzflg,'C'    ; got here via Control-C?
  687.     jne    kermt7            ; ne = no
  688.     cmp    flags.extflg,0        ; exit flag set?
  689.     jne    kermt5            ; ne = yes, skip msg, do cleanup
  690.     mov    dx,offset ermes3    ; say command not executed
  691.     mov    ah,prstr        ; print    the error message in dx
  692.     int    dos
  693. kermt5:    cmp    flags.cxzflg,'C'    ; user Control-C abort?
  694.     jne    kermt7            ; ne = no, do normal operations
  695.     cmp    taklev,0        ; in a Take file?
  696.     je    kermt7            ; e = no        
  697.     call    takclos            ; close take file, release buffer
  698.     jmp    short kermt5        ; close any other take files
  699. kermt7:    cmp    flags.extflg,0        ; exit flag set?
  700.     jne    krmend            ; ne = yes, exit
  701.     jmp    kermit            ; e = no, get next command
  702.  
  703. krmend:    mov    flags.cxzflg,0        ; reset each time
  704.     mov    flags.extflg,0
  705.     call    far ptr exmacro        ; find on_exit macro
  706.     jc    krmend2            ; c = not found
  707.                     ; perform ON_EXIT macro
  708. krmend1:cmp    taklev,0        ; finished with macros?
  709.     je    krmend2            ; e = yes
  710.     mov    dx,prmptr        ; get prompt string address
  711.     call    mprompt              ; set master reparse address to here
  712.     mov    flags.cxzflg,0        ; reset each time
  713.     and    flags.remflg,not dserver ; turn off server mode bit
  714.     mov    dx,offset comtab    ; keyword table
  715.     xor    bx,bx            ; no help
  716.         mov    ah,cmkey
  717.     mov    comand.impdo,1        ; allow implied "DO macro"
  718.     mov    comand.cmcr,1        ; allow bare CR's
  719.     call    comnd
  720.     jc    krmend2            ; c = failure
  721.     mov    comand.impdo,0        ; only on initial keyword, not here
  722.     call    bx            ; call the routine returned in BX
  723.     jnc    krmend1            ; nc = success, keep doing commands
  724.                     ; end of ON_EXIT macro processing
  725. krmend2:cmp    taklev,0        ; in a Take file?
  726.     je    krmend3            ; e = no        
  727.     call    takclos            ; close take file, release buffer
  728.     jmp    short krmend2        ; close any other take files
  729. krmend3:mov    bx,lclexit        ; addr of sys dependent exit routine
  730.     or    bx,bx            ; sys dependent routines want service?
  731.     jz    krmend4            ; z = no
  732.     call    bx            ; call it
  733.     jnc    krmend4            ; nc = close
  734.     jmp    kermit            ; c = do not close
  735. krmend4:call    serrst            ; just in case the port wasn't reset
  736.     call    clscpi            ; close log files
  737.     call    far ptr emsclose    ; close and return EMS memory
  738.     mov    dl,origd        ; original disk drive
  739.     dec    dl            ; want A == 0
  740.     mov    ah,seldsk        ; reset original disk just in case
  741.     int    dos
  742.     mov    dx,offset orgdir    ; restore original directory
  743.     mov    ah,chdir
  744.     int    dos
  745.     push    ds            ; save ds around these DOS calls
  746.     mov    ax,cs            ; compose full address of ^C routine
  747.     mov    ds,ax            ; segment is the code segment
  748.     mov    dx,offset in3ad        ; restore Control-C interrupt vector
  749.     mov    al,23H            ; interrupt 23H
  750.     mov    ah,setintv        ; set interrupt vector
  751.     int    dos            ; ah, that's better
  752.     mov    dx,offset ceadr        ; DOS's Critical Error handler
  753.     mov    al,24h            ; interrupt 24h
  754.     mov    ah,setintv        ; do replacement (put it back)
  755.     int    dos
  756.     pop    ds
  757.     call    cbrestore        ; restore state of Control-Break Chk
  758.     mov    ah,4cH            ; terminate process
  759.     mov    al,errlev        ; return error level
  760.     int    dos
  761.     ret
  762. START    ENDP
  763.  
  764. ; This is the 'EXIT' command.  It leaves KERMIT and returns to DOS
  765.  
  766. EXIT    PROC    NEAR
  767.     mov    ah,cmeol
  768.     call    comnd            ; get a confirm
  769.     jc    exit1            ; c = failure
  770.     mov    flags.extflg,1        ; set the exit-Kermit flag
  771. exit1:    ret
  772. EXIT    ENDP
  773. code    ends
  774.  
  775. code1    segment
  776.     assume    cs:code1
  777. exmacro    proc    far            ; perform on_exit() macro
  778.     push    bx
  779.     push    cx
  780.     push    si
  781.     mov    bx,offset mcctab    ; table of macro names
  782.     mov    cl,[bx]            ; number of names in table
  783.     xor    ch,ch
  784.     jcxz    exmacx            ; z = empty table, do nothing
  785.     inc    bx            ; point to length of first name
  786. exmac2:    mov    ax,[bx]            ; length of this name
  787.     cmp    ax,onexlen        ; length same as desired keyword?
  788.     jne    exmac3            ; ne = no, search again
  789.     mov    si,bx
  790.     add    si,2            ; point at first char of name
  791.     push    cx            ; save name counter
  792.     push    di            ; save reg
  793.     mov    cx,onexlen        ; length of name
  794.     mov    di,offset onexit+2    ; point at desired macro name text
  795.     push    es            ; save reg
  796.     push    ds
  797.     pop    es            ; make es use data segment
  798.     cld
  799.     repe    cmpsb            ; match strings
  800.     pop    es            ; need current si below
  801.     pop    di
  802.     pop    cx            ; recover saved regs
  803.     jne    exmac3            ; ne = no match
  804.     mov    onexit+2,0        ; change name to be invisible
  805.     mov    byte ptr [bx+2],0    ; change macro table name too
  806.     jmp    short exmac4        ; e = matched
  807. exmac3:    add    bx,ax            ; step to next name, add name length
  808.     add    bx,4            ; + count and def word ptr
  809.     loop    exmac2            ; try next name
  810. exmacx:    pop    si            ; no macro, fail
  811.     pop    cx
  812.     pop    bx
  813.     stc                ; say failure
  814.     ret
  815.  
  816. exmac4:    cmp    taklev,maxtak        ; room in Take level?
  817.     jge    exmacx            ; ge = no, exit with no action
  818.     inc    taklev            ; increment take level
  819.     add    takadr,size takinfo    ; make a new Take entry/macro
  820.     mov    bx,takadr        ; point to current macro structure
  821.     mov    ax,ds            ; text is in our data seg
  822.     mov    [bx].takbuf,ax        ; seg of definition string struc
  823.     mov    [bx].takptr,offset onexit+2 ; where to read next command char
  824.     mov    [bx].takcnt,onexlen    ; number of chars in definition
  825.     mov    [bx].takargc,0        ; store macro argument count
  826.     mov    [bx].taktyp,0ffh    ; flag as a macro
  827.     pop    si
  828.     pop    cx
  829.     pop    bx
  830.     clc                ; say success
  831.     ret
  832. exmacro    endp
  833.  
  834. ; Close and return EMS memory, uses emsrbhandle and emsgshandle
  835. emsclose proc    far
  836.     mov    ah,45h            ; release handle and memory
  837.     mov    dx,emsrbhandle        ; handle
  838.     or    dx,dx            ; is handle valid (not -1)?
  839.     jl    emsclose1        ; l = no
  840.     int    67h            ; ems interrupt
  841. emsclose1:mov    emsrbhandle,-1
  842.     mov    ah,45h            ; release handle and memory
  843.     mov    dx,emsgshandle        ; handle
  844.     or    dx,dx            ; is handle valid (not -1)?
  845.     jl    emsclose2        ; l = no
  846.     int    67h            ; ems interrupt
  847. emsclose2:mov    emsgshandle,-1
  848.     ret
  849. emsclose endp
  850. code1    ends
  851.  
  852. code    segment
  853.     assume    cs:code
  854. ; TAKE commands    from a file, and allow a path name
  855. TAKE    PROC    NEAR
  856.     mov    kstatus,kssuc        ; global status, success
  857.     cmp    taklev,maxtak        ; at the limit?
  858.     jl    take1            ; l = no
  859.     mov    ah,prstr
  860.     mov    dx,offset erms30    ; complain
  861.     int    dos
  862.     stc                ; failure
  863.     ret
  864. take1:    mov    dx,offset tmpbuf    ; work buffer
  865.     mov    tmpbuf,0
  866.     mov    bx,offset filmsg    ; Help in case user types "?"
  867.     mov    comand.cmkeep,1        ; keep file open
  868.     mov    ah,cmword        ; get file name
  869.     call    comnd
  870.     jc    take1a            ; c = failure
  871.     mov    ah,cmeol
  872.     call    comnd
  873.     jc    take1a            ; c = failure
  874.     mov    ax,offset tmpbuf    ; point to name again
  875.     cmp    tmpbuf,0        ; empty filespec?
  876.     jne    take2            ; ne = no
  877.     mov    ah,prstr
  878.     mov    dx,offset ermes1    ; say more parameters needed
  879.     int    dos
  880.     stc
  881. take1a:    ret
  882.                     ; TAKE2: enter with ax=filename ptr
  883. TAKE2:    call    spath            ; is it around?
  884.     jc    take3            ; no, go complain
  885.     mov    dx,ax            ; point to name from spath
  886.     mov    ah,open2        ; open file
  887.     xor    al,al            ; 0 = open for reading
  888.     cmp    dosnum,300h        ; at or above DOS 3?
  889.     jb    take2a            ; b = no, so no shared access
  890.     or    al,40h            ; open for reading, deny none
  891. take2a:    int    dos
  892.     jnc    take4            ; nc = opened ok, keep going
  893.     mov    ax,dx            ; recover filename pointer
  894. take3:    push    ax
  895.     mov    ah,prstr
  896.     mov    dx,offset erms31
  897.     int    dos
  898.     pop    ax
  899.     mov    dx,ax            ; asciiz file name
  900.     call    prtasz            ; display it
  901.     mov    kstatus,kstake        ; status, Take failed
  902.     clc                ; we've done all error displays
  903.     ret
  904.                     ; TAKE4: enter with ax=filename ptr
  905. TAKE4:    call    takopen            ; open take buffer in macro space
  906.     jc    take6            ; c = failure
  907.     push    bx
  908.     mov    bx,takadr        ; get current frame ptr
  909.     mov    [bx].takhnd,ax        ; save file handle
  910.     mov    [bx].taktyp,0feh     ; mark as 2.0 file handle
  911.     pop    bx
  912.     cmp    flags.takflg,0        ; echoing Take files?
  913.     je    take5            ; e = no
  914.     mov    ah,prstr
  915.     mov    dx,offset crlf
  916.     int    dos
  917. take5:    call    takrd            ; get a buffer full of data
  918.     clc                ; success
  919. take6:    ret
  920. TAKE    ENDP
  921.  
  922. TAKRD    PROC    NEAR
  923.     push    ax
  924.     push    bx
  925.     push    cx    
  926.     push    dx
  927.     mov    bx,takadr
  928.     cmp    [bx].taktyp,0feh    ; get type of take (file?)
  929.     jne    takrd1            ; ne = no, do not read from disk
  930.     mov    cx,tbufsiz-2        ; # of bytes to read
  931.     mov    ax,[bx].takbuf        ; segment of Take buffer
  932.     push    bx            ; save frame address
  933.     mov    bx,[bx].takhnd        ; file handle is stored here
  934.     push    ds            ; save ds
  935.     mov    ds,ax            ; set ds to Take buffer segment
  936.     mov    dx,2            ; ds:dx = buffer, skip count word
  937.     mov    ah,readf2        ; read file
  938.     int    dos
  939.     pop    ds
  940.     pop    bx            ; restore frame address
  941.     jnc    takrd2            ; nc = successful read
  942. takrd1:    xor    ax,ax            ; error, say zero bytes read
  943. takrd2:    mov    [bx].takcnt,ax        ; number of bytes read
  944.     mov    [bx].takptr,2        ; offset of first new character
  945.     pop    dx
  946.     pop    cx
  947.     pop    bx
  948.     pop    ax
  949.     ret
  950. TAKRD    ENDP
  951.  
  952. ; TAKE-QUIT  (STOP)  Exit all Take files immediately but gracefully
  953.  
  954. TAKEQIT PROC    NEAR
  955.     xor    ax,ax
  956.     mov    errlev,al        ; return value in ERRORLEVEL
  957.     mov    kstatus,ax        ; and in STATUS
  958.     mov    ah,cmline        ; get optional error value and msg
  959.     mov    bx,offset rdbuf+1
  960.     mov    rdbuf,'\'        ; in case the user did not specify
  961.     mov    dx,offset stophlp    ; help on numerical argument
  962.     mov    comand.cmcr,1        ; bare c/r's allowed
  963.     call    comnd
  964.     mov    comand.cmcr,0        ; restore normal state
  965.     jc    takqit3            ; c = failure
  966.     mov    ah,cmeol        ; confirm
  967.     call    comnd
  968.     jc    takqit3
  969.     mov    si,offset rdbuf
  970.     cmp    byte ptr [si+1],'\'    ; user specified?
  971.     jne    takqit1            ; ne = no, use ours
  972.     inc    si            ; yes, use theirs
  973. takqit1:call    katoi            ; convert to number in ax
  974.     jc    takqit2            ; c = not a number
  975.     mov    errlev,al        ; return value in ERRORLEVEL
  976.     mov    kstatus,ax        ; and in STATUS
  977. takqit4:lodsb                ; read a msg char
  978.     or    al,al            ; null terminator?
  979.     jz    takqit2            ; z = empty string
  980.     cmp    al,' '            ; leading white space?
  981.     je    takqit4            ; be = leading white space
  982.     dec    si            ; backup to non-white char
  983.     mov    di,si            ; msg pointer, convert in-place
  984.     call    cnvlin            ; convert braces and numbers
  985.     mov    dx,offset crlf
  986.     mov    ah,prstr
  987.     int    dos
  988.     mov    dx,si            ; message pointer
  989.     call    prtasz
  990. takqit2:xor    ch,ch
  991.     mov    cl,taklev        ; number of Take levels active
  992.     jcxz    takqit3            ; z = none
  993.     cmp    cmdlinetake,cl        ; have DOS level command line?
  994.     jae    takqit3            ; ae = yes, don't close it here
  995.     call    takclos            ; close current Take file
  996.     jmp    short takqit2        ; repeat until all are closed
  997. takqit3:clc                ; success
  998.     ret
  999. TAKEQIT    ENDP
  1000.  
  1001. ; put mskermit.ini onto take stack if it exists.  Just like
  1002. ; the take command, except it doesn't read a filename
  1003.  
  1004. rdinit    proc    near            ; read Kermit init file
  1005.     mov    ax,offset ininm2    ; default name to try
  1006.     cmp    decbuf,0        ; alternate init file given?
  1007.     je    rdini1            ; ne = no
  1008.     mov    ax,offset decbuf    ; yes, use it
  1009.     call    take2            ; let Take do error msgs
  1010.     clc                ; force success
  1011.     ret
  1012. rdini1:    call    spath            ; is it around?
  1013.     jc    rdini2            ; no, ignore file
  1014.     mov    dx,ax            ; point to name from spath
  1015.     mov    ah,open2        ; open file
  1016.     xor    al,al            ; 0 = open for reading
  1017.     cmp    dosnum,300h        ; at or above DOS 3?
  1018.     jb    rdini1a            ; b = no, so no shared access
  1019.     or    al,40h            ; open for reading, deny none
  1020. rdini1a:int    dos
  1021.     jc    rdini2            ; c = no ini file found, ignore
  1022.     call    take4            ; use TAKE command to complete work
  1023.     clc                ; ignore errors
  1024. rdini2:    ret
  1025. rdinit    endp
  1026.  
  1027. ; Patcher.  Patch file, MSRxxx.PCH or MSKERMIT.PCH has the following format:
  1028.  
  1029. ; 301 \Xxxxx    Text to display upon successful patch load
  1030. ; ;301 for V3.01.  For xxxx, see below
  1031. ; ; optional comment lines may appear anywhere after the 1st
  1032. ; ; xxxx in 1st line = total paragraphs in memory image.  Use \X if hex.
  1033. ; DS:xxxx xx xx        ; optional comment.  DS (or CS) are case insensitive
  1034. ; CS:xxxx xx xx xx    ; locations must be 4 hex chars, contents must be 2
  1035. ;
  1036. ; The 1st xx is the original value of the 1st byte @seg:offset for comparison.
  1037. ; A 00 value says don't compare.  Subsequent xx's are replacement bytes.
  1038. ; CS & DS lines may be intermixed.  AS & BS segments may be used when some
  1039. ; external module sets words aseg & bseg to a seg-base.
  1040. ; This mechanism expects file msscmd.obj to be linked first.
  1041.  
  1042. PATCH    proc
  1043.     mov    dx,offset rdbuf        ; optional path prefix
  1044.     mov    rdbuf,0
  1045.     mov    bx,offset pathlp
  1046.     mov    ah,cmword
  1047.     call    comnd
  1048.     jc    patch1
  1049.     mov    ah,cmeol
  1050.     call    comnd
  1051.     jc    patch1
  1052.     xor    ax,ax
  1053.     xchg    al,patched        ; clear and test patched
  1054.     test    al,al
  1055.     jz    patch1            ; z = disabled or done
  1056.     xchg    ah,flags.takflg        ; clear take flag, don't echo patches
  1057.     mov    byte ptr temp,ah    ; but save it
  1058.     call    ptchr
  1059.     mov    al,byte ptr temp    ; restore take flag
  1060.     mov    flags.takflg,al
  1061.     jc    patch2            ; c = NG
  1062. patch1:    ret
  1063.  
  1064. patch2:    mov    dx,offset ermes8    ; Fatal error
  1065.     mov    ah,prstr
  1066.     int    dos
  1067.     jmp    krmend            ; force exit
  1068.  
  1069. ptchr:    mov    dx,offset rdbuf        ; optional path
  1070.     call    strlen            ; get length, if any
  1071.     jcxz    ptchr1            ; z = nothing
  1072.     mov    si,dx
  1073.     add    si,cx
  1074.     cmp    byte ptr [si-1],'\'    ; ends with path specifier?
  1075.     je    ptchr1            ; e = yes
  1076.     cmp    byte ptr [si-1],':'    ; or a drive specifier?
  1077.     je    ptchr1            ; e = yes
  1078.     mov    word ptr [si],'\'+0    ; add '\' + null
  1079. ptchr1:    mov    di,offset rdbuf+66    ; path goes here
  1080.     mov    si,offset rdbuf+140    ; filename goes here, discard
  1081.     mov    byte ptr [di],0        ; clear
  1082.     call    fparse            ; split optional path
  1083.     mov    si,offset ptchnam    ; add name of patch file
  1084.     push    di
  1085.     call    strcat
  1086.     mov    ax,di            ; setup filename pointer for rdini1
  1087.     call    rdini1        ; let rdini try to find it & do take stuff
  1088.     pop    di
  1089.     jnc    ptch1            ; nc = file msrxxx.pch was found
  1090.     mov    si,offset ptchnam2    ; try alternate name
  1091.     mov    byte ptr [di],0        ; insert terminator
  1092.     call    strcat            
  1093.     mov    ax,di            ; setup filename pointer for rdini1
  1094.     call    rdini1        ; let rdini try to find it & do take stuff
  1095.     jnc    ptch1            ; nc = file msrxxx.pch was found
  1096.     mov    dx,offset ermes7    ; say file not found
  1097.     mov    ah,prstr
  1098.     int    dos
  1099.     clc
  1100.     ret
  1101.  
  1102. ptch1:    mov    al,taklev        ; remember initial take level
  1103.     mov    tmpbuf,al        ; when it changes it is EOF & done
  1104.     mov    comand.cmcr,1        ; bare cr's ok, to prevent prserr @EOF
  1105.     call    ptchrl            ; read 1st line's 1st 'word'
  1106.     jc    ptch2            ; c = trouble
  1107.     jz    ptch3            ; z = EOF
  1108.     mov    si,offset tmpbuf+1
  1109.     xchg    ah,al            ; line length to ah for atoi
  1110.     xor    al,al
  1111.     call    atoi            ; convert version string to integer
  1112.     jc    ptch2            ; c = bad number, or none
  1113.     cmp    ax,version        ; does it match this version?
  1114.     je    ptch4            ; e = yes
  1115. ptch2:    mov    al,tmpbuf        ; if take level has changed,
  1116.     xor    al,taklev        ;  we're already out of patch file
  1117.     jnz    ptch3            ; nz = change in take level
  1118.     call    takclos            ; close patch file
  1119. ptch3:    mov    dx,offset ermes6
  1120.     mov    ah,prstr        ; issue warning msg
  1121.     int    dos
  1122.     clc
  1123.     ret
  1124.  
  1125. ptch4:    mov    dx,offset tmpbuf+1
  1126.     call    ptchrw            ; read 2nd "word", 1st line
  1127.     jc    ptch2            ; c = NG
  1128.     mov    si,offset tmpbuf+1
  1129.     call    katoi            ; convert 2nd "magic number"
  1130.     jc    ptch2            ; c = NG
  1131.     cmp    ax,totpar    ; is it the total paragraphs memini computed?
  1132.     jne    ptch2            ; ne = no
  1133.     mov    bx,offset buff    ; place to stash 1st lines patch/version msg
  1134.     xor    dx,dx
  1135.     mov    ah,cmline        ; read it
  1136.     call    comnd
  1137.  
  1138. ptch5:    call    ptchrl            ; read CS:xxxx or DS:xxxx
  1139.     jc    ptch6
  1140.     jz    ptch7            ; z = EOF
  1141.     cmp    ax,7            ; were 7 chars read?
  1142.     jne    ptch6            ; ne = no
  1143.     mov    si,offset tmpbuf+1
  1144.     and    word ptr[si],not 2020h    ; convert to upper case
  1145.     cld
  1146.     lodsb                ; get the seg char
  1147.     cmp    word ptr[si],':S'     ; S:, actually
  1148.     je    ptch8            ; e = ok
  1149. ptch6:    stc                ; error exit
  1150.     ret
  1151.  
  1152. ptch7:    mov    ah,prstr
  1153.         mov    dx,offset verident    ; display version header
  1154.         int    dos
  1155.     clc
  1156.     ret
  1157.  
  1158. ptch8:    push    ds
  1159.     pop    es
  1160.     mov    di,offset segstr
  1161.     mov    cx,lsegstr        ; search for seg char in segstr
  1162.     repne    scasb
  1163.     jne    ptch6            ; ne = not found
  1164.     sub    di,offset segstr+1    ; distance spanned
  1165.     shl    di,1            ; make a word index
  1166.     mov    bx,segtab[di]        ; bx = seg-base
  1167.     or    bx,bx            ; seg-base = 0, disabled for patching
  1168.     jz    ptch6            ; z = 0, no patching
  1169.     mov    word ptr[si],'X\'     ; put '\X' in front of hex for katoi
  1170.     call    katoi            ; convert location
  1171.     jc    ptch6            ; c= NG
  1172.     push    bx            ; save seg being patched
  1173.     push    ax            ; save location being patched
  1174.     mov    tmpbuf+64,0        ; clear replacement byte count
  1175. ptch9:    mov    dx,offset tmpbuf+4
  1176.     call    ptchrw            ; read replacement byte follwing '\X'
  1177.     jnc    ptch11            ; nc = OK
  1178. ptch10:    pop    ax            ; clean stack & error return
  1179.     pop    bx
  1180.     stc
  1181.     ret
  1182.  
  1183. ptch11:    or    ax,ax            ; EOL?
  1184.     jnz    ptch13            ; nz = no
  1185.     mov    si,offset tmpbuf+64
  1186.     cld
  1187.     lodsb                ; replacement byte count
  1188.     cmp    al,2            ; gotta be at least 2
  1189.     jb    ptch10            ; b = too few
  1190.     xor    ch,ch
  1191.     mov    cl,al            ; replacement count
  1192.     pop    di            ; patch location
  1193.     pop    es            ; patch segment
  1194.     lodsb                ; al = comparison byte
  1195.     or    al,al            ; key value to ignore comparison?
  1196.     jz    ptch12            ; z = 0, yes
  1197.     cmp    byte ptr es:[di],al     ; do read check on memory image
  1198.     jne    ptch6            ; ne = no match, fail now
  1199. ptch12:    dec    cx            ; adjust for comparison byte
  1200.     rep    movsb            ; make patch
  1201.     jmp    ptch5            ; loop to read next line
  1202.  
  1203. ptch13:    cmp    al,2            ; 2 chars req'd for replacement byte
  1204.     jne    ptch10            ; ne = bad
  1205.     mov    si,offset tmpbuf+2    ; convert it
  1206.     call    katoi
  1207.     jc    ptch10            ; c = bad number or none
  1208.     mov    si,offset tmpbuf+64    ; --> replacement byte counted string
  1209.     inc    byte ptr[si]        ; bump count
  1210.     mov    bl,[si]
  1211.     xor    bh,bh
  1212.     mov    byte ptr[si+bx],al    ; stash replacement byte
  1213.     jmp    short ptch9        ; loop for next byte
  1214.  
  1215. ptchrl:    mov    dx,offset crlf        ; read 1st word, next line to tmpbuf+1
  1216.     call    prompt
  1217.     mov    dx,offset tmpbuf+1
  1218.     call    ptchrw
  1219.     jc    ptchrb            ; c = NG
  1220.     mov    dl,tmpbuf
  1221.     xor    dl,taklev
  1222.     jz    ptchra            ; z = not EOF
  1223.     xor    ax,ax            ; set z flag for EOF
  1224.     ret
  1225.  
  1226. ptchra:    or    ax,ax            ; empty or comment line?
  1227.     jz    ptchrl            ; z = empty or comment, ignore
  1228. ptchrb:    ret
  1229.  
  1230. ptchrw:    mov    ah,cmword
  1231.     mov    comand.cmper,1    ; prohibit substitution variable expansion
  1232.     xor    bx,bx            ; 'help' ptr
  1233.     call    comnd            ; line length is in ax
  1234.     ret
  1235. PATCH    endp
  1236.  
  1237. ; Get command line into a Take macro buffer. Allow "-f filspec" to override
  1238. ; normal mskermit.ini initialization filespec, allow command "stay" to
  1239. ; suppress automatic exit to DOS at end of command line execution. [jrd]
  1240.  
  1241. gcmdlin    proc    near
  1242.     mov    cmdlinetake,0        ; flag for DOS command line Take
  1243.     mov    word ptr decbuf,0    ; storage for new init filename
  1244.     push    es
  1245.     cld
  1246.     mov    es,psp            ; address psp
  1247.     xor    ch,ch
  1248.     mov    cl,es:byte ptr[cline]    ; length of cmd line from DOS
  1249.     jcxz    gcmdl1            ; z = empty line
  1250.     mov    si,cline+1        ; point to actual line
  1251. gcmdl0:    cmp    byte ptr es:[si],' '    ; skip over leading whitespace
  1252.     ja    gcmdl2            ; a = non-whitespace
  1253.     inc    si
  1254.     loop    gcmdl0            ; fall through on all whitespace
  1255. gcmdl1:    jmp    gcmdl14            ; common exit jump point
  1256. gcmdl2:    inc    cx            ; include DOS's c/r
  1257.     call    takopen            ; open take buffer in macro space
  1258.     mov    bx,takadr
  1259.     mov    byte ptr [bx].taktyp,0ffh ; mark as a macro
  1260.     mov    [bx].takcnt,0        ; length of text
  1261.     mov    es,[bx].takbuf        ; segment of buffer, from takopen
  1262.     mov    di,2            ; skip count word
  1263.     push    psp
  1264.     pop    ds            ; DS = PSP
  1265.     xor    dx,dx            ; clear brace count
  1266. gcmdl3:    or    cx,cx            ; anything left?
  1267.     jle    gcmdl10            ; le = no
  1268.     lodsb                ; get a byte from PSP's command line
  1269.     dec    cx            ; one less char in input string
  1270.     cmp    al,','            ; comma?
  1271.     jne    gcmdl4            ; no, keep going
  1272.     or    dx,dx            ; inside braces?
  1273.     jnz    gcmdl9            ; nz = yes, retain embedded commas
  1274.     mov    al,cr            ; convert to cr
  1275.     jmp    short gcmdl9        ; store it
  1276. gcmdl4:    call    bracechk        ; check for curly braces
  1277.     jc    gcmdl9            ; c = found and counted brace
  1278.     or    dx,dx            ; outside braces?
  1279.     jnz    gcmdl9            ; nz = no, ignore flag
  1280.     cmp    al,'-'            ; starting a flag?
  1281.     jne    gcmdl9            ; ne = no
  1282.     mov    ah,[si]            ; get flag letter
  1283.     or    ah,20h            ; convert to lower case
  1284.     cmp    ah,'f'            ; 'f' for init file replacement?
  1285.     jne    gcmdl9            ; ne = no
  1286.     inc    si            ; accept flag letter
  1287.     dec    cx
  1288. gcmdl5:    or    cx,cx            ; anything to read?
  1289.     jle    gcmdl10            ; le = exhausted supply
  1290.     lodsb                ; get filespec char from psp
  1291.     dec    cx            ; one less char in source buffer
  1292.     cmp    al,' '            ; in whitespace?
  1293.     jbe    gcmdl5            ; be = yes, scan it off
  1294.     dec    si            ; backup to real text
  1295.     inc    cx
  1296.                     ; copy filspec to buffer decbuf
  1297.     push    es            ; save current destination pointer
  1298.     push    di            ;  which is in es:di (Take buffer)
  1299.     mov    di,data            ; set es:di to regular decbuf
  1300.     mov    es,di
  1301.     lea    di,decbuf        ; where filespec part goes
  1302.     mov    word ptr es:[di],0    ; plant safety terminator
  1303. gcmdl6:    lodsb                ; get filespec char
  1304.     dec    cx            ; one less available
  1305.     cmp    al,' '            ; in printables?
  1306.     jbe    gcmdl7            ; be = no, all done
  1307.     cmp    al,','            ; comma command separator?
  1308.     je    gcmdl7            ; e = yes, all done
  1309.     stosb                ; store filespec char
  1310.     or    cx,cx            ; any chars left?
  1311.     jg    short gcmdl6        ; g = yes
  1312. gcmdl7:    mov    byte ptr es:[di],0    ; end filespec on a null
  1313.     pop    di            ; recover destination pointer es:di
  1314.     pop    es
  1315. gcmdl8:    or    cx,cx            ; strip trailing whitespace
  1316.     jle    gcmdl10            ; le = nothing left
  1317.     lodsb
  1318.     dec    cx
  1319.     cmp    al,' '            ; white space?
  1320.     jbe    gcmdl8            ; be = yes, strip it
  1321.     cmp    al,','            ; at next command?
  1322.     je    gcmdl10            ; e = yes, skip our own comma
  1323.     dec    si            ; back up to reread the char
  1324.     inc    cx
  1325.     jmp    gcmdl3            ; read more command text
  1326.                     ; end of flag analysis
  1327. gcmdl9:    stosb                ; deposit most recent char
  1328. gcmdl10:or    cx,cx            ; anything left to read?
  1329.     jg    gcmdl3            ; g = yes, loop
  1330.                     ;
  1331.     mov    ax,data            ; restore segment registers
  1332.     mov    ds,ax
  1333.     mov    si,[bx].takbuf        ; get segment of Take buffer
  1334.     mov    es,si
  1335.     mov    si,2            ; skip count word
  1336.     mov    cx,di            ; current end pointer, (save di)
  1337.     sub    cx,si            ; current ptr minus start offset
  1338.     mov    [bx].takcnt,cx        ; chars in buffer so far
  1339.     mov    es:word ptr [0],cx    ; store count word
  1340.     xor    dx,dx            ; brace count
  1341.     or    cx,cx
  1342.     jg    gcmdl11            ; g = material at hand
  1343.     call    takclos            ; empty take file
  1344.     jmp    short gcmdl14        ; finish up
  1345.                     ; scan for command "stay"
  1346. gcmdl11:mov    ax,es:[si]        ; get 2 bytes, cx and si are set above
  1347.     inc    si            ; increment by only one char
  1348.     dec    cx
  1349.     call    bracechk        ; check for braces
  1350.     jc    gcmdl12            ; c = brace found
  1351.     cmp    al,' '            ; separator?
  1352.     jbe    gcmdl12            ; be = yes, keep looking
  1353.     cmp    al,','             ; comma separator?
  1354.     je    gcmdl12            ; e = yes
  1355.     or    dx,dx            ; within braces?
  1356.     jnz    gcmdl12            ; nz = yes, skip STAY search
  1357.     or    ax,2020h        ; convert to lower case
  1358.     cmp    ax,'ts'            ; first two letters of stay
  1359.     jne    gcmdl12            ; ne = no match
  1360.     mov    ax,es:[si+1]        ; next two letters (stay vs status)
  1361.     or    ax,2020h        ; convert to lower case
  1362.     cmp    ax,'ya'            ; same as our pattern?
  1363.     jne    gcmdl12            ; ne = no match
  1364.     add    si,3            ; char after "stay"
  1365.     sub    cx,3
  1366.                     ; check for separator or end of macro
  1367.     cmp    byte ptr es:[si],' '    ; next char is a separator?
  1368.     jbe    gcmdl13            ; be = yes, found correct match
  1369.     cmp    byte ptr es:[si],','    ; or comma separator?
  1370.     je    gcmdl13            ; e = yes
  1371.     or    cx,cx            ; at end of macro?
  1372.     jle    gcmdl13            ; yes, consider current match correct
  1373. gcmdl12:or    cx,cx            ; done yet? ("stay" not found)
  1374.     jg    gcmdl11            ; g = not yet, look some more
  1375.     mov    cmdlinetake,1        ; remember doing DOS cmd line Take
  1376.     mov    si,offset eexit        ; append command "exit"
  1377.     mov    cx,leexit        ; length of string "exit"
  1378.     add    [bx].takcnt,cx
  1379.     rep    movsb            ; copy it into the Take buffer
  1380. gcmdl13:mov    [bx].takptr,2        ; init buffer ptr
  1381.     mov    cx,[bx].takcnt        ; count of bytes in buffer
  1382.     mov    es:[0],cx        ; count of bytes in Take buffer
  1383. gcmdl14:pop    es
  1384.     ret
  1385. gcmdlin    endp
  1386.  
  1387. ; Curly brace checker. Examine (and preserve) char in AL. Count up/down
  1388. ; braces in dx because DS is unknown here
  1389. bracechk proc    near
  1390.     cmp    al,braceop        ; opening brace?
  1391.     jne    bracech1        ; ne = no
  1392.     inc    dx            ; count up braces
  1393.     stc                ; say brace seen
  1394.     ret
  1395. bracech1:cmp    al,bracecl        ; closing brace
  1396.     jne    bracech3        ; ne = no
  1397.     sub    dx,1            ; count down with sign
  1398.     jns    bracech2        ; ns = no underflow
  1399.     xor    dx,dx            ; don't go below zero
  1400. bracech2:stc                ; say brace detected
  1401.     ret
  1402. bracech3:clc                ; say brace not found
  1403.     ret
  1404. bracechk endp
  1405.  
  1406. ; Enter with ax pointing to file name.  Searches path for given file,
  1407. ; returns with ax pointing to whole name, or carry set if file can't be found.
  1408. SPATH    proc    near
  1409.     call    isfile            ; does it exist as it is?
  1410.     jc    spath0            ; c = no, prepend path elements
  1411.     test    byte ptr filtst.dta+21,10H ; subdirectory name?
  1412.     jnz    spath0            ; nz = yes, not desired file
  1413.     clc
  1414.     ret
  1415. spath0:    push    es            ; save es around work
  1416.     push    bx
  1417.     push    si
  1418.     push    di
  1419.     mov    bx,ax            ; save filename pointer in bx
  1420.     mov    si,ax
  1421.     xor    dl,dl            ; no '\' seen yet
  1422.     cld
  1423. spath1:    lodsb
  1424.     cmp    al,2fh            ; contains fwd slash path characters?
  1425.     je    spath1a
  1426.     cmp    al,5ch            ; or backslash?
  1427.     jne    spath2            ; no, keep going
  1428. spath1a:mov    dl,1            ; remember we've seen them
  1429. spath2:    or    al,al
  1430.     jnz    spath1            ; copy name in
  1431.     or    dl,dl            ; look at flag
  1432.     jz    spath3            ; no path, keep looking
  1433.     jmp    short spath9        ; embedded path, fail
  1434.  
  1435. spath3:    call    skpath            ; search kermit's path
  1436.     jnc    spath8a            ; nc = located file
  1437.     mov    si,pthadr        ; offset of PATH= string in environment
  1438.     mov    es,psp
  1439.     mov    di,es:word ptr[env]    ; pick up environment segment
  1440.     mov    es,di
  1441. spath4:    cmp    byte ptr es:[si],0    ; end of PATH= string?
  1442.     je    spath9            ; e = yes, exit loop
  1443.     mov    di,offset decbuf+64    ; place to put name
  1444. spath5:    mov    al,byte ptr es:[si]    ; get a byte from environment string
  1445.     inc    si
  1446.     cmp    al,';'            ; end of this part?
  1447.     je    spath7            ; yes, break loop
  1448.     or    al,al            ; maybe end of string?
  1449.     jnz    spath6            ; nz = no, keep going
  1450.     dec    si            ; back up to null for later rereading
  1451.     jmp    short spath7        ; and break loop
  1452. spath6:    mov    byte ptr [di],al    ; else stick in dest string
  1453.     inc    di
  1454.     jmp    short spath5        ; and continue
  1455. spath7:    push    si            ; save this ptr
  1456.     mov    si,bx            ; this is user's file name
  1457.     cmp    byte ptr [di-1],2fh    ; does path end with switch char?
  1458.     je    spath8            ; yes, don't put one in
  1459.     cmp    byte ptr [di-1],5ch    ; how about this one?
  1460.     je    spath8            ; yes, don't put it in
  1461.     mov    byte ptr [di],5ch    ; else add one
  1462.     inc    di
  1463. spath8:    lodsb                ; get filename character
  1464.     mov    byte ptr [di],al    ; copy filename char to output buffer
  1465.     inc    di
  1466.     or    al,al            ; end of string?
  1467.     jnz    spath8            ; nz = no, copy rest of name
  1468.     pop    si            ; restore postion in path string
  1469.     mov    ax,offset decbuf+64
  1470.     call    isfile            ; is it a file?
  1471.     jc    spath4            ; c = no, keep looking
  1472.     test    byte ptr filtst.dta+21,10H ; subdirectory name?
  1473.     jnz    spath4            ; nz = yes
  1474. spath8a:pop    di
  1475.     pop    si
  1476.     pop    bx
  1477.     pop    es
  1478.     clc
  1479.     ret                ; return success (carry clear)
  1480. spath9:    mov    ax,bx            ; restore original filename pointer
  1481.     pop    di            ; restore regs
  1482.     pop    si
  1483.     pop    bx
  1484.     pop    es
  1485.     stc                ; no file found
  1486.     ret
  1487. spath    endp
  1488.  
  1489. ; Search Kermit's path for file. Return carry clear if found, else carry set.
  1490. ; Worker for spath above.
  1491. skpath    proc    near
  1492.     mov    si,seg kpath        ; Kermit's path
  1493.     mov    es,si
  1494.     mov    si,offset kpath
  1495.     mov    di,offset decbuf+64    ; place to put name
  1496. skpath1:mov    al,es:[si]        ; get a byte from string
  1497.     inc    si
  1498.     cmp    al,';'            ; end of this part?
  1499.     je    skpath3            ; yes, break loop
  1500.     or    al,al            ; maybe end of string?
  1501.     jnz    skpath2            ; nz = no, keep going
  1502.     dec    si            ; back up to null for later rereading
  1503.     jmp    short skpath3        ; and break loop
  1504. skpath2:mov    byte ptr [di],al    ; else stick in dest string
  1505.     inc    di
  1506.     jmp    short skpath1        ; and continue
  1507. skpath3:cld
  1508.     mov    si,bx            ; this is user's file name
  1509.     cmp    byte ptr [di-1],2fh    ; does path end with switch char?
  1510.     je    skpath4            ; yes, don't put one in
  1511.     cmp    byte ptr [di-1],5ch    ; how about this one?
  1512.     je    skpath4            ; yes, don't put it in
  1513.     mov    byte ptr [di],5ch    ; else add one
  1514.     inc    di
  1515. skpath4:lodsb                ; get filename character
  1516.     mov    byte ptr [di],al    ; copy filename char to output buffer
  1517.     inc    di
  1518.     or    al,al            ; end of string?
  1519.     jnz    skpath4            ; nz = no, copy rest of name
  1520.     mov    ax,offset decbuf+64
  1521.     push    bx
  1522.     call    isfile            ; is it a file?
  1523.     pop    bx
  1524.     jnc    skpath5            ; nc = yes
  1525.     ret
  1526. skpath5:test    byte ptr filtst.dta+21,10H ; subdirectory name?
  1527.     jnz    skpath6            ; nz = yes
  1528.     clc                ; report file found (AX as offset)
  1529.     ret
  1530. skpath6:stc                ; report failure
  1531.     ret
  1532. skpath    endp
  1533.  
  1534. ; Put Kermit's Enviroment Path indicator into string kpath
  1535. mkkpath    proc    near            
  1536.     mov    dx,offset rdbuf
  1537.     mov    word ptr rdbuf,0
  1538.     xor    bx,bx
  1539.     mov    ah,cmword        ; get port address number
  1540.     call    comnd
  1541.     jnc    mkkpath1        ; nc = success
  1542.     ret
  1543. mkkpath1:mov    cx,ax            ; get string length
  1544.     push    si
  1545.     push    di
  1546.     push    es
  1547.     mov    si,offset rdbuf        ; source
  1548.     mov    di,seg kpath        ; storage spot
  1549.     mov    es,di
  1550.     mov    di,offset kpath
  1551.     cld
  1552.     rep    movsb            ; copy
  1553.     mov    byte ptr es:[di],0    ; terminate
  1554.     pop    es
  1555.     pop    di
  1556.     pop    si
  1557.     ret
  1558. mkkpath    endp
  1559.  
  1560. ; Put offset of PATH= string in pthadr
  1561. getpath    proc    near
  1562.     push    bx
  1563.     push    cx
  1564.     push    dx
  1565.     mov    bx,offset pthnam    ; thing    to find
  1566.     mov    cx,pthlen        ; length of it
  1567.     mov    pthadr,0        ; init offset to zero
  1568.     call    getenv            ; get environment value
  1569.     mov    pthadr,dx
  1570.     pop    dx
  1571.     pop    cx
  1572.     pop    bx
  1573.     ret
  1574. getpath    endp
  1575.  
  1576. ; getcsp: copy COMSPEC= environment string into cmspbuf
  1577. ; getssp: copy SHELL=   environment string into shellbuf
  1578. getcsp    proc    near
  1579.     mov    bx,offset cmspnam    ; find COMSPEC=
  1580.     mov    cx,cmsplen        ; it's length
  1581.     mov    di,offset cmspbuf    ; where to store string
  1582.     jmp    short getccom        ; do common worker
  1583.  
  1584. getssp:    mov    bx,offset shellnam    ; find SHELL=
  1585.     mov    cx,shellen        ; it's length
  1586.     mov    di,offset shellbuf    ; where to store string
  1587.     
  1588. getccom:push    es
  1589.     call    getenv            ; get environment offset into dx
  1590.     mov    si,dx            ; address of COMSPEC= string
  1591.     mov    es,psp
  1592.     mov    bx,es:word ptr[env]    ; pick up environment address
  1593.     mov    es,bx
  1594.     push    ds            ; save ds
  1595.     push    ds            ; make ds point to environment seg
  1596.     push    es            ; make es point to data segment
  1597.     pop    ds
  1598.     pop    es
  1599.     cld
  1600. getcs1:    lodsb                ; get a byte from environment
  1601.     cmp    al,' '            ; space or less?
  1602.     jg    getcs2            ; g = no, keep copying
  1603.     xor    al,al            ; terminate string on spaces etc
  1604. getcs2:    stosb                ; store it in destination
  1605.     or    al,al            ; at end of string yet?
  1606.     jnz    getcs1            ; nz = no, keep copying
  1607.     pop    ds            ; recover ds
  1608.     pop    es
  1609.     ret
  1610. getcsp    endp
  1611.  
  1612. ; Get Kermit parameters from the Environment. Parameters are commands like
  1613. ; regular commands except they do not appear in the SET main table and are
  1614. ; separated from one another by semicolons. They appear after KERMIT=.
  1615. ; Do not allow Take/Macros to be created by any of these commands.
  1616. ; On fatal error exits with carry set and flags.extflg = 1
  1617. getparm    proc    near
  1618.     push    ax
  1619.     push    bx
  1620.     push    cx
  1621.     push    dx
  1622.     push    si
  1623.     push    di
  1624.     push    es
  1625.     mov    es,psp            ; segment of our PSP
  1626.     mov    ax,es:word ptr[env]    ; pick up environment address
  1627.     mov    es,ax
  1628.     mov    bx,offset kerenv    ; Environment word to find, asciiz
  1629.     mov    dx,bx
  1630.     call    strlen            ; length of its string to cx
  1631.     call    getenv            ; return dx = offset in environment
  1632.     jnc    getpar1            ; nc = success
  1633.     jmp    getpar9            ; c = not found
  1634. getpar1:push    ds            ; save regular DS
  1635.     push    dx            ; push Environment offset, then seg
  1636.     push    es
  1637.     call    takopen            ; open Take buffer in macro space
  1638.     jnc    getpar2            ; nc = success
  1639.     mov    flags.extflg,1        ; say exit now
  1640.     pop    es            ; clean stack
  1641.     pop    dx
  1642.     pop    ds
  1643.     jmp    getparx            ; exit with fatal error
  1644.  
  1645. getpar2:mov    bx,takadr        ; bx = Take data structure
  1646.     mov    byte ptr [bx].taktyp,0ffh ; mark as a macro
  1647.     mov    [bx].takcnt,0        ; length of text
  1648.     mov    es,[bx].takbuf        ; ES = segment of buffer, from takopen
  1649.     mov    di,2            ; skip count word field for es:di
  1650.     pop    ds            ; pop Environment segment (was in ES)
  1651.     pop    si            ;  and seg, DS:SI is now Environment
  1652.     xor    cx,cx            ; line length counter
  1653. getpar3:lodsb                ; read an Environment character
  1654.     or    al,al            ; null (EOL)?
  1655.     jz    getpar5            ; z = yes, stop here
  1656.     cmp    al,';'            ; semicolon separator?
  1657.     jne    getpar4            ; ne = no
  1658.     mov    al,CR            ; replace semicolon with carriage ret
  1659. getpar4:stosb                ; store char in Take buffer
  1660.     inc    cx            ; count line length
  1661.     jmp    short getpar3        ; get more text, until a null
  1662.  
  1663. getpar5:mov    al,CR            ; terminate line, regardless
  1664.     stosb
  1665.     inc    cx            ; count terminator
  1666.     pop    ds            ; restore regular DS
  1667.     mov    [bx].takcnt,cx        ; chars in Take/macro buffer
  1668.     mov    es:[0],cx        ; store count byte
  1669.     mov    [bx].takptr,2        ; init buffer read ptr to first char
  1670.     jcxz    getpar8            ; z = nothing left, exit
  1671.                     ; parse each item as a command
  1672. getpar6:mov    comand.cmquiet,1    ; no screen display
  1673.     mov    dx,offset nulprmpt    ; set null prompt
  1674.     call    prompt
  1675.     cmp    flags.extflg,0        ; exit flag set?
  1676.     jne    getpar8            ; ne = yes, exit this routine now
  1677.     mov    dx,offset initab    ; table of initialization routines
  1678.     xor    bx,bx            ; no explict help text
  1679.     mov    comand.cmcr,1        ; allow bare CR's
  1680.     mov    comand.impdo,0        ; do not search Macro table
  1681.         mov    ah,cmkey        ; match a keyword
  1682.     call    comnd
  1683.     jc    getpar7            ; c = failure
  1684.     mov    comand.cmcr,0        ; no more bare CR's
  1685.     call    bx            ; call the routine returned in BX
  1686.                     ; ignore failures (carry bit set)
  1687. getpar7:cmp    taklev,0        ; finished Take file?
  1688.     je    getpar8            ; e = yes
  1689.     cmp    flags.extflg,0        ; exit flag set?
  1690.     je    getpar6            ; e = no, finish all commands
  1691.  
  1692. getpar8:call    takclos            ; close our take file, if open
  1693. getpar9:mov    flags.extflg,0        ; do not leave this flag set
  1694.     clc                ; clear for success
  1695. getparx:mov    comand.cmquiet,0    ; regular screen echoing
  1696.     pop    es
  1697.     pop    di
  1698.     pop    si
  1699.     pop    dx
  1700.     pop    cx
  1701.     pop    bx
  1702.     pop    ax
  1703.     ret
  1704. getparm    endp
  1705.  
  1706. ; Locate string variable in Environment
  1707. ; bx = variable to find (usually including =), cx = length of variable name.
  1708. ; Returns dx = offset within Environment of char following the name and
  1709. ; carry clear, else carry set and dx unchanged.
  1710. getenv    proc    near
  1711.     push    ax
  1712.     push    cx
  1713.     push    si
  1714.     push    di
  1715.     push    es
  1716.     mov    es,psp
  1717.     mov    ax,es:word ptr[env]    ; pick up environment address
  1718.     mov    es,ax
  1719.     xor    di,di            ; start at offset 0 in segment
  1720. geten1:    cmp    es:byte ptr [di],0    ; end of environment?
  1721.     je    geten3            ; yes, forget it
  1722.     push    cx            ; save counter
  1723.     push    di            ; and offset
  1724.     mov    si,bx
  1725.     cld
  1726.     repe    cmpsb            ; search for name
  1727.     pop    di
  1728.     pop    cx            ; restore these
  1729.     je    geten2            ; found it, break loop
  1730. getenv5:push    cx            ; preserve again
  1731.     mov    cx,0ffffh        ; bogus length
  1732.     xor    al,al            ; 0 = marker to look for
  1733.     repne    scasb            ; search for it
  1734.     pop    cx            ; restore length
  1735.     jmp    short geten1        ; loop thru rest of environment
  1736. geten2:    add    di,cx            ; skip to definition
  1737. geten6:    mov    si,bx            ; name
  1738.     add    si,cx            ; length
  1739.     cmp    byte ptr [si-1],'='    ; caller wanted '=' as last char?
  1740.     je    geten7            ; e = yes, and we found it
  1741.     mov    al,es:[di]        ; get next char
  1742.     cmp    al,'='            ; at the equals sign?
  1743.     je    geten7            ; e = yes
  1744.     inc    di            ; point at next char
  1745.     cmp    al,' '            ; white space?
  1746.     jbe    geten6            ; be = yes, skip over this
  1747.     dec    di            ; backup
  1748.     jmp    short getenv5        ; not a match, keep looking
  1749. geten7:    mov    dx,di            ; store offset of string
  1750.     clc                ; carry clear for success
  1751.     jmp    short geten4
  1752. geten3:    stc                ; carry set for failure
  1753. geten4:    pop    es
  1754.     pop    di
  1755.     pop    si
  1756.     pop    cx
  1757.     pop    ax
  1758.     ret
  1759. getenv    endp
  1760.  
  1761. ; Get thousands separator from DOS Country Information
  1762. gettsep    proc    near
  1763.     mov    ah,38h            ; Get Country Information
  1764.     mov    dx,offset tmpbuf    ; temp buffer
  1765.     int    dos
  1766.     mov    bx,7            ; assume DOS 3+ position in buffer
  1767.     cmp    byte ptr dosnum+1,3    ; DOS 3 or above?
  1768.     jae    gettse1            ; ae = yes
  1769.     mov    bx,4            ; for DOS 2.1
  1770.     cmp    dosnum,210h        ; earlier than version 2.1?
  1771.     jae    gettse1            ; ae = no
  1772.     mov    al,','            ; use comma for old DOS's
  1773. gettse1:mov    al,tmpbuf[bx]        ; get thousands separator char
  1774.     mov    thsep,al        ; save it
  1775.     mov    al,tmpbuf        ; get time/date format code
  1776.     mov    tdfmt,al        ; save it
  1777.     ret
  1778. gettsep    endp
  1779.  
  1780. STAY    PROC    NEAR
  1781.     clc
  1782.     ret
  1783. STAY    ENDP
  1784.  
  1785. CLS    proc    near            ; Clear command level screen
  1786.     mov    ah,cmeol        ; get a confirmation
  1787.     call    comnd
  1788.     jc    cls1            ; c = failure
  1789.     call    cmblnk            ; blank the screen
  1790.     call    locate            ; put cursor at home position
  1791. cls1:    ret
  1792. CLS    endp
  1793.  
  1794. COMNT    PROC    NEAR            ; COMMENT command
  1795.     mov    ah,cmline
  1796.     mov    bx,offset tmpbuf
  1797.     xor    dx,dx
  1798.     call    comnd
  1799.     jc    comnt1
  1800.     mov    ah,cmeol
  1801.     call    comnd
  1802. comnt1:    ret
  1803. COMNT    ENDP
  1804.  
  1805. ; change working directory
  1806. cwdir    proc    near
  1807.     mov    kstatus,kssuc        ; global status
  1808.     mov    ah,cmword
  1809.     mov    dx,offset tmpbuf
  1810.     mov    bx,offset pthmsg
  1811.     mov    word ptr tmpbuf,0
  1812.     call    comnd            ; get drive/dir spec, if any
  1813.     mov    ah,cmeol
  1814.     call    comnd
  1815.     jnc    cwd1
  1816.     ret                ; c = failure
  1817. cwd1:    mov    si,offset tmpbuf    ; cdsr wants drive/path ptr in si
  1818.     call    cdsr            ; common CD sub-routine
  1819.     jnc    cwd2            ; nc = success
  1820.     mov    kstatus,ksgen        ; global status for unsuccess
  1821. cwd2:    cmp    taklev,0        ; in a Take file or macro?
  1822.     je    cwd3            ; e = no, do echo
  1823.     cmp    flags.takflg,0        ; ok to echo?
  1824.     je    cwd4            ; e = no
  1825. cwd3:    push    dx
  1826.     mov    dx,offset crlf        ; msgs from cdsr don't include this
  1827.     mov    ah,prstr        ; so let's do it now
  1828.     int    dos
  1829.     pop    dx
  1830.     call    prtasz            ; output current drive/path or err msg
  1831. cwd4:    clc
  1832.     ret
  1833. cwdir    endp
  1834.  
  1835. ; CDSR processes both CD & REM CD.  Entered with si --> drive/path, it returns
  1836. ; dx --> ASCIIZ current drive/path, w/carry clear, if successful, or error msg
  1837. ; w/carry set, if not.
  1838. CDSR    PROC
  1839.     mov    kstatus,kssuc        ; global status
  1840.     xor    cx,cx            ; 0 for default drive, if none
  1841.     cmp    byte ptr[si],ch        ; any drive/path?
  1842.     je    cdsr4            ; e = no, format current drive/path
  1843.     cmp    byte ptr[si+1],':'    ; is drive specified?
  1844.     jne    cdsr1            ; ne = no
  1845.     mov    cl,[si]            ; drive letter
  1846.     cmp    byte ptr[si+2],ch    ; any path?
  1847.     jne    cdsr1            ; ne = yes
  1848.     mov    word ptr[si+2],'.'    ; append dot+null as path to kludge DOS
  1849. cdsr1:    call    dskspace        ; test for drive, spec'd by cl, ready
  1850.     jnc    cdsr2            ; nc = ready
  1851.     mov    spcmsg3,cl        ; insert drive letter ret'd by dskspace
  1852.     mov    dx,offset spcmsg2+2    ; in err msg.  dx --> msg w/o cr,lf
  1853.     mov    kstatus,ksgen        ; global status
  1854.     ret                ; carry is set
  1855.  
  1856. cdsr2:    mov    dx,si            ; where chdir wants it
  1857.     mov    ah,chdir
  1858.     int    dos
  1859.     jnc    cdsr3            ; nc = success
  1860.     mov    dx,offset ermes4    ; ret carry set, dx --> err msg
  1861.     ret
  1862.  
  1863. cdsr3:    mov    dl,cl            ; uc drive letter ret'd by dskspace
  1864.     sub    dl,'A'            ; A = 0 for seldsk
  1865.     mov    ah,seldsk
  1866.     int    dos
  1867.     inc    dl            ; A = 1 for curdsk
  1868.     mov    curdsk,dl
  1869. cdsr4:    push    si            ; use caller's buffer for cur dr/path
  1870.     mov    ax,':@'            ; al = 'A' - 1, ah = ':'
  1871.     add    al,curdsk        ; al = drive letter
  1872.     mov    [si],ax            ; stash drive:
  1873.     inc    si
  1874.     inc    si
  1875.     mov    byte ptr[si],'\'    ; add \
  1876.     inc    si
  1877.     mov    ah,gcd            ; gcd fills in path as ASCIIZ
  1878.     xor    dl,dl            ; use current drive
  1879.     int    dos
  1880.     pop    dx            ; return caller's buffer pointer in dx
  1881.     clc
  1882.     ret
  1883. CDSR    ENDP
  1884.  
  1885. ; Erase specified file(s). Add protection of ignore hidden, subdir, volume
  1886. ; label and system files. 9 Jan 86 [jrd]
  1887. DELETE    PROC    NEAR            ; includes paths and "?*" wildcards
  1888.     mov    kstatus,kssuc        ; global status
  1889.     mov    si,offset delcmd    ; del command
  1890.     mov    di,offset tmpbuf
  1891.     call    strcpy
  1892.     mov    dx,offset tmpbuf
  1893.     call    strlen            ; get its length
  1894.     add    di,cx            ; point at terminator
  1895.     mov    temp,di            ; remember starting spot
  1896.     mov    ah,cmline        ; get a line
  1897.     mov    bx,di            ; where to place the file spec
  1898.     mov    dx,offset filmsg    ; help message
  1899.     call    comnd
  1900.     jc    delet0            ; c = failure
  1901.     push    ax
  1902.     mov    ah,cmeol
  1903.     call    comnd
  1904.     pop    ax
  1905.     jc    delet0
  1906.     cmp    apctrap,0        ; disable from APC
  1907.     jne    delet0            ; ne = yes
  1908.     or    ax,ax            ; anything given?
  1909.     jnz    delet1            ; nz = yes
  1910.     mov    ah,prstr
  1911.     mov    dx,offset ermes1    ; say need something
  1912.     int    dos
  1913.     clc                ; say success
  1914. delet0:    mov    kstatus,ksgen        ; global status
  1915.     ret
  1916.  
  1917. delet1:    mov    di,temp            ; start of filespec
  1918.     xor    cl,cl            ; disk drive letter
  1919.     cmp    byte ptr [di+1],':'    ; drive specified?
  1920.     jne    delet2            ; ne = no
  1921.     mov    cl,[di]            ; get drive letter
  1922. delet2:    call    dskspace        ; compute space, get letter into CL
  1923.     jnc    delet3            ; nc = success
  1924.     mov    spcmsg3,cl        ; put drive letter in msg
  1925.     mov    dx,offset spcmsg2    ; error message
  1926.     call    prtasz
  1927.     mov    kstatus,ksgen        ; global status
  1928.     clc
  1929.     ret                ; and ignore this command
  1930. delet3:    mov    si,offset tmpbuf    ; del cmd
  1931.     jmp    crun            ; join run cmd from there
  1932. DELETE    ENDP
  1933.  
  1934. ; Space <optional drive letter>
  1935.  
  1936. CHKDSK    PROC    NEAR            ; Space command
  1937.     mov    kstatus,kssuc        ; global status
  1938.     mov    dx,offset tmpbuf    ; buffer
  1939.     mov    tmpbuf,0        ; init to null
  1940.     mov    bx,offset dskmsg    ; help message
  1941.     mov    ah,cmword        ; get optional drive letter
  1942.     call    comnd            ; ignore errors
  1943.     mov    ah,cmeol
  1944.     call    comnd
  1945.     jnc    chkdsk1            ; nc = success
  1946.     ret                ; failure
  1947. chkdsk1:mov    cl,tmpbuf        ; set drive letter
  1948.     call    dskspace        ; compute space, get letter into CL
  1949.     jnc    chkdsk2            ; nc = success
  1950.     and    cl,5fh            ; to upper case
  1951.     mov    spcmsg3,cl        ; insert drive letter
  1952.     mov    dx,offset spcmsg2    ; say drive not ready
  1953.     call    prtasz
  1954.     mov    kstatus,ksgen        ; global status
  1955.     clc
  1956.     ret
  1957.     
  1958. chkdsk2:mov    spcmsg1,cl        ; insert drive letter
  1959.     mov    di,offset tmpbuf    ; work space for lnout
  1960.     mov    word ptr[di],0a0dh    ; cr/lf
  1961.     mov    word ptr[di+2],'  '    ; add two spaces
  1962.     add    di,4
  1963.     call    lnouts            ; use thousands separator
  1964.     mov    si,offset spcmsg
  1965.     call    strcat            ; add text to end of message
  1966.     mov    dx,offset tmpbuf
  1967.     call    prtasz            ; print asciiz string
  1968.     clc
  1969.     ret
  1970. CHKDSK    ENDP
  1971.  
  1972. ; Compute disk free space (bytes) into long word dx:ax.
  1973. ; Enter with disk LETTER in CL (use null if current disk).
  1974. ; Returns uppercase drive letter in CL.
  1975. ; Returns carry set if drive access error. Changes AX, DX.
  1976.  
  1977. DSKSPACE PROC    NEAR
  1978.     mov    dl,cl            ; desired disk letter, or null
  1979.     or    dl,dl            ; use current disk?
  1980.     jnz    dskspa1            ; nz = no
  1981.     mov    ah,gcurdsk        ; get current disk
  1982.     int    dos
  1983.     add    al,'A'            ; make 0 ==> A
  1984.     mov    dl,al
  1985. dskspa1:and    dl,5fh            ; convert to upper case
  1986.     mov    cl,dl            ; return upper case drive letter in CL
  1987.     sub    dl,'A'-1        ; 'A' is 1, etc
  1988.     push    bx
  1989.     push    cx
  1990.     mov    ah,36h            ; get disk free space, bx=sect/cluster
  1991.     int    dos            ; dx:ax=sectors, cx=bytes/sector
  1992.     cmp    ax,0ffffh        ; error response?
  1993.     jne    dskspa2            ; ne = no
  1994.     pop    cx
  1995.     pop    bx
  1996.     stc                ; return error
  1997.     ret
  1998. dskspa2:mul    bx            ; sectors/cluster * clusters = sectors
  1999.     mov    bx,dx            ; save high word of sectors (> 64K)
  2000.     mul    cx            ; bytes = sectors * bytes/sector
  2001.     push    ax            ; save low word of bytes
  2002.     mov    ax,bx            ; recall sectors high word
  2003.     mov    bx,dx            ; save current bytes high word
  2004.     mul    cx            ; high word sectors * bytes/sector
  2005.     add    ax,bx            ; new high bytes + old high bytes
  2006.     mov    dx,ax            ; store high word in dx
  2007.     pop    ax            ; space is in dx:ax as a long word
  2008.     pop    cx
  2009.     pop    bx
  2010.     clc
  2011.     ret
  2012. DSKSPACE ENDP
  2013.  
  2014. ; Get directory    listing
  2015. DIRECT    PROC    NEAR
  2016.     mov    kstatus,kssuc        ; global status
  2017.     mov    si,offset dircmd    ; dir command
  2018.     mov    di,offset tmpbuf
  2019.     call    strcpy
  2020.     mov    dx,offset tmpbuf
  2021.     call    strlen            ; get its length
  2022.     add    di,cx            ; point at terminator
  2023.     mov    temp,cx            ; remember length
  2024.     mov    ah,cmline        ; parse with cmline to allow switches
  2025.     mov    bx,di            ; next available byte
  2026.     mov    dx,offset filmsg    ; help message 
  2027.     call    comnd
  2028.     jnc    direct1            ; nc = success
  2029. direct0:mov    kstatus,ksgen        ; global status
  2030.     ret                ; failure
  2031. direct1:mov    ah,cmeol
  2032.     call    comnd
  2033.     jc    direct0
  2034.     mov    word ptr [bx],0        ; plant terminator
  2035.     mov    cl,curdsk        ; current drive number ('A'=1)
  2036.     add    cl,'A'-1        ; make a letter
  2037.     mov    si,offset tmpbuf
  2038.     push    si
  2039.     add    si,temp            ; user's text after ' dir '
  2040.     cmp    byte ptr [si+1],':'    ; drive specified?
  2041.     jne    direct2            ; ne = no, use current drive
  2042.     mov    cl,[si]            ; get drive letter from buffer
  2043. direct2:call    dskspace        ; check for drive ready
  2044.     pop    si
  2045.     jnc    direct3            ; nc = drive ready
  2046.     mov    spcmsg3,cl        ; insert letter
  2047.     mov    dx,offset spcmsg2    ; say drive is not ready
  2048.     call    prtasz
  2049.     mov    kstatus,ksgen        ; global status
  2050.     stc
  2051.     ret
  2052. direct3:jmp    crun            ; join run cmd from there
  2053. DIRECT    ENDP
  2054.  
  2055. ; This is the 'HELP' command.  It gives a list of the commands
  2056.  
  2057. HELP    PROC    NEAR
  2058.     mov    kstatus,kssuc        ; global status
  2059.     mov    ah,cmeol
  2060.     call    comnd            ; get a confirm
  2061.     jnc    help1            ; nc = success
  2062.     ret                ; failure
  2063.  
  2064. help1:    push    ds            ; changing data segments!
  2065.     push    es
  2066.     mov    ax,ds
  2067.     mov    es,ax            ; for escchr
  2068.     mov    ax,data1        ; new data segment
  2069.     mov    ds,ax
  2070.     ; warning
  2071.     assume    ds:data1
  2072.     mov    ah,prstr        ; show Quick help summary screen
  2073.     mov    dx,offset qckhlp
  2074.     int    dos
  2075.     mov    ah,conout
  2076.     mov    dl,es:trans.escchr    ; get Kermit escape character
  2077.     add    dl,40h            ; convert to printable
  2078.     push    dx            ; save it for repeats below
  2079.     int    dos
  2080.     mov    ah,prstr
  2081.     mov    dx,offset qckhlp1    ; more help text
  2082.     int    dos
  2083.     mov    ah,conout
  2084.     pop    dx
  2085.     push    dx
  2086.     int    dos
  2087.     mov    ah,prstr
  2088.     mov    dx,offset qckhlp2    ; more help text
  2089.     int    dos
  2090.     pop    dx            ; recover current escape char
  2091.     mov    ah,conout
  2092.     int    dos
  2093.     mov    ah,prstr
  2094.     mov    dx,offset qckhlp3    ; end of help message
  2095.     int    dos
  2096.     mov    ah,coninq        ; get a keystroke, quietly
  2097.     int    dos
  2098.     cmp    es:flags.cxzflg,'C'    ; Control-C?
  2099.     je    helpend            ; e = yes, quit now
  2100.     cmp    al,3
  2101.     je    helpend
  2102.     cmp    al,' '            ; space bar?
  2103.     je    help2            ; ne = no, skip second screen
  2104.     jmp    short helpend        ; switch data segments
  2105.  
  2106. help2:    mov    ah,prstr
  2107.     mov    dx,offset qckhlp4    ; more of help message
  2108.     int    dos
  2109.     mov    ah,coninq        ; get a keystroke, quietly
  2110.     int    dos
  2111.     cmp    es:flags.cxzflg,'C'    ; Control-C?
  2112.     je    helpend            ; e = yes, quit now
  2113.     cmp    al,3
  2114.     je    helpend
  2115.     cmp    al,' '            ; space bar?
  2116.     je    help3            ; ne = no, skip second screen
  2117.     jmp    short helpend        ; switch data segments
  2118.  
  2119. help3:    mov    ah,prstr        ; show second Quick help summary
  2120.     mov    dx,offset qckhlp5
  2121.     int    dos
  2122.     mov    ah,coninq
  2123.     int    dos
  2124.     cmp    es:flags.cxzflg,'C'    ; Control-C?
  2125.     je    helpend            ; e = yes, quit now
  2126.     cmp    al,3
  2127.     je    helpend
  2128.     cmp    al,'?'            ; query mark?
  2129.     je    helpquery        ; e = yes do main query help
  2130.     mov    ah,prstr
  2131.     mov    dx,offset qckhlp6
  2132.     int    dos
  2133.     mov    ah,coninq
  2134.     int    dos
  2135.     cmp    es:flags.cxzflg,'C'    ; Control-C?
  2136.     je    helpend            ; e = yes, quit now
  2137.     cmp    al,3
  2138.     je    helpend
  2139.     cmp    al,'?'            ; query mark?
  2140.     je    helpquery        ; e = yes do main query help
  2141.     mov    ah,prstr
  2142.     mov    dx,offset qckhlp7
  2143.     int    dos
  2144. helpend:pop    es
  2145.     pop    ds            ; restore regular data seg data
  2146.     ; warning
  2147.     assume    ds:data
  2148.     clc
  2149.     ret
  2150. helpquery:
  2151.     pop    es
  2152.     pop    ds            ; restore regular data seg data
  2153.     ; warning
  2154.     assume    ds:data
  2155.     mov    ah,prstr        ; show help summary screen
  2156.     mov    dx,offset crlf        ; a few blank lines
  2157.     int    dos
  2158.     int    dos
  2159.     int    dos
  2160.     mov    dx,offset tophlp    ; show usual cryptic help
  2161.     int    dos
  2162. helpx:    clc
  2163.     ret
  2164. HELP    ENDP
  2165.  
  2166. ; the version command - print our version number
  2167. prvers    proc    near
  2168.     mov    kstatus,kssuc        ; global status
  2169.     mov    ah,cmeol
  2170.     call    comnd
  2171.     jc    prvers1            ; c = failure
  2172.     mov    ah,prstr
  2173.     mov    dx,offset crlf
  2174.     int    dos
  2175.     mov    ah,prstr
  2176.     mov    dx,offset machnam    ; display machine name
  2177.     int    dos
  2178.     mov    ah,prstr        ; display the version header
  2179.     mov    dx,offset verident
  2180.     int    dos
  2181.     clc
  2182. prvers1:ret
  2183. prvers    endp
  2184.  
  2185. ; SHOW command dispatcher
  2186. showcmd    proc    near
  2187.     mov    ah,cmkey
  2188.     mov    dx,offset shotab
  2189.     xor    bx,bx            ; no canned help
  2190.     call    comnd
  2191.     jc    showc1            ; c = failure
  2192.     jmp    bx            ; execute the handler
  2193. showc1:    ret                ; failure
  2194. showcmd    endp
  2195.  
  2196. ; the type command - type out a file
  2197. typec    proc    near
  2198.     mov    kstatus,kssuc        ; global status
  2199.     mov    si,offset typcmd    ; type command
  2200.     mov    di,offset tmpbuf
  2201.     call    strcpy
  2202.     mov    dx,offset tmpbuf
  2203.     call    strlen            ; get its length
  2204.     add    di,cx            ; point at terminator
  2205.     mov    temp,di            ; save place for later
  2206.     mov    ah,cmline        ; parse with cmline, allows | more
  2207.     mov    bx,di            ; next available byte
  2208.     mov    dx,offset filmsg    ; In case user wants help
  2209.     call    comnd
  2210.     jc    typec1            ; c = failure
  2211.     push    ax
  2212.     mov    ah,cmeol
  2213.     call    comnd
  2214.     pop    ax
  2215.     jc    typec1
  2216.     or    ax,ax            ; any text given?
  2217.     jnz    typec2            ; nz = yes
  2218.     mov    ah,prstr
  2219.     mov    dx,offset ermes1    ; say need more info
  2220.     int    dos
  2221.     mov    kstatus,ksgen        ; global status
  2222.     clc
  2223. typec1:    ret
  2224. typec2:    mov    byte ptr [bx],0        ; plant terminator
  2225.     mov    si,temp            ; start of filespec
  2226.     xor    cl,cl            ; say local drive
  2227.     cmp    byte ptr [si+1],':'    ; drive given?
  2228.     jne    typec3            ; ne = no
  2229.     mov    cl,[si]            ; get drive letter
  2230. typec3:    call    dskspace        ; check for drive ready
  2231.     jnc    typec4
  2232.     mov    spcmsg3,cl        ; put drive letter in msg
  2233.     mov    dx,offset spcmsg2    ; error message
  2234.     call    prtasz
  2235.     mov    kstatus,ksgen        ; global status
  2236.     clc
  2237.     ret                ; and ignore this command
  2238. typec4:    mov    si,offset tmpbuf
  2239.     jmp    short crun        ; join run cmd from there
  2240. typec    endp
  2241.  
  2242. ; PUSH to DOS (run another copy of Command.com or equiv)
  2243. ; entry fpush (fast push...) pushes without waiting for a confirm
  2244. dopush    proc    near
  2245.     mov    ah,cmeol
  2246.     call    comnd
  2247.     jnc    fpush            ; nc = success
  2248.     ret                ; failure
  2249. fpush:    mov    si,offset tmpbuf    ; a dummy buffer
  2250.     mov    byte ptr [si],0        ; plant terminator
  2251.     mov    dx,offset cmspbuf    ; always use command.com
  2252.     cmp    shellbuf,0        ; SHELL= present?
  2253.     je    crun4            ; e = no, use COMSPEC= name
  2254.     mov    dx,offset shellbuf    ; use SHELL= name
  2255.     jmp    short crun4        ; go run it
  2256.     stc
  2257.     ret
  2258. dopush    endp
  2259.  
  2260. ; Run a program from within Kermit
  2261. RUN    PROC    NEAR
  2262.     mov    ah,cmline        ; get program name and any arguments
  2263.     mov    bx,offset tmpbuf    ; place for user's text
  2264.     mov    dx,offset runmsg    ; In case user wants help
  2265.     call    comnd
  2266.     jnc    run1            ; nc = success
  2267.     ret                ; failure
  2268. run1:    cmp    apctrap,0        ; disable from APC
  2269.     je    run1a            ; e = no
  2270.     stc                ; yes, fail
  2271.     ret
  2272. run1a:    or    ax,ax            ; byte count
  2273.     jnz    run2            ; nz = have program name
  2274.     mov    ah,prstr        ; else complain
  2275.     mov    dx,offset ermes1    ; need more info
  2276.     int    dos
  2277.     clc
  2278.     ret
  2279. run2:    mov    si,offset tmpbuf    ; source of text
  2280.     mov    di,si
  2281.     call    cnvlin
  2282.     jmp    short crun
  2283. RUN    ENDP
  2284.  
  2285. ; crun - run an arbitrary program.    Rewritten by [jrd]
  2286. ; Enter with ordinary asciiz command in si (such as Dir *.asm)
  2287. ; Append a c/r and a null terminator and then ask command.com to do it
  2288. ; Set errlev with DOS errorlevel from subprocess.
  2289. CRUN    proc    near
  2290.     mov    ah,prstr        ; output crlf before executing comnd
  2291.     mov    dx,offset crlf        ; [lba]
  2292.     int    dos
  2293.     mov    di,offset tmpbuf    ; where to put full command line text
  2294.     cmp    si,di            ; same place?
  2295.     je    crun1            ; e = yes, don't copy ourself
  2296.     call    strcpy            ; si holds source text
  2297. crun1:    mov    si,offset slashc    ; DOS command begins with slashc area
  2298.     mov    dx,offset slashc+1    ; si points to /c part of command line
  2299.     call    strlen            ; get its length into cx
  2300.     push    bx
  2301.     mov    bx,dx
  2302.     add    bx,cx
  2303.     mov    byte ptr [bx],cr    ; end string with a c/r for dos
  2304.     inc    cx            ; count the c/r
  2305.     mov    byte ptr [bx+1],0    ; and terminate
  2306.     pop    bx
  2307.     mov    [si],cl            ; put length of argument here
  2308.     mov    dx,offset cmspbuf    ; always use command.com
  2309. crun4:    mov    exearg+2,si        ; pointer to argument string
  2310.     mov    exearg+4,ds        ; segment of same
  2311.     cmp    lclsusp,0        ; sys dependent routine to call
  2312.     je    crun5            ; e = none
  2313.     mov    bx,lclsusp        ; address to call
  2314.     push    dx            ; preserve name in dx
  2315.     call    bx            ; call sys dependent suspend routine
  2316.     pop    dx
  2317. crun5:    push    dx            ; preserve name in dx
  2318.     call    serrst            ; reset serial port (if active)
  2319.     call    cbrestore        ; restore state of Control-Break Chk
  2320.     pop    dx
  2321.     mov    es,psp            ; point to psp again
  2322.     mov    exearg+8,es        ; segment of psp, use our def fcb's
  2323.     mov    exearg+12,es        ; segment of psp, ditto, for fcb 2
  2324.     mov    ax,es:word ptr [env]    ; get environment ptr
  2325.     mov    exearg,ax        ; put into argument block
  2326.     mov    ax,ds
  2327.     mov    es,ax            ; put es segment back
  2328.     mov    bx,offset exearg    ; es:bx points to exec parameter block
  2329.     mov    ax,ss            ; save ss:sp
  2330.     mov    word ptr ssave+2,ax
  2331.     mov    word ptr ssave,sp
  2332.     xor    al,al            ; 0 = load and execute (DX has name)
  2333.     mov    ah,exec
  2334.     int    dos            ; go run command.com
  2335.     mov    bx,data            ; restore segment registers
  2336.     mov    ds,bx            ; reset data segment
  2337.     mov    es,bx            ; and extra segment
  2338.     cli
  2339.     mov    bx,word ptr ssave+2
  2340.     mov    ss,bx            ; and stack segment
  2341.     mov    sp,word ptr ssave    ; restore stack ptr
  2342.     sti
  2343.     jnc    crun9            ; nc = no error
  2344.     mov    ah,prstr        ; failure, complain
  2345.     mov    dx,offset erms37
  2346.     int    dos
  2347.     mov    dx,offset cmspbuf    ; path\name of command.com
  2348.     call    prtasz            ; asciiz
  2349.     mov    kstatus,ksgen        ; global status
  2350. crun9:    mov    ah,setdma        ; restore dma buffer pointer
  2351.     mov    dx,offset buff
  2352.     int    dos            ; restore dma address!!
  2353.     call    cboff            ; turn off DOS BREAK check
  2354.     cmp    lclrest,0        ; sys dependent routine to call?
  2355.     je    crun10            ; e = none
  2356.     mov    bx,lclrest        ; get routine's address
  2357.     call    bx            ; call sys dependent restore routine
  2358. crun10:    clc
  2359.     ret
  2360. CRUN    ENDP
  2361. code    ends
  2362.  
  2363. code1    segment
  2364.     assume    cs:code1 
  2365. ; Replace Int 23h and Int 24h with our own handlers
  2366. ; Revised to ask DOS for original interrupt vector contents, as suggested by
  2367. ; Jack Bryans. 9 Jan 1986 jrd
  2368. ; Modified again 30 August 1986 [jrd]
  2369. SETINT    PROC    FAR
  2370.     push    es            ; save registers
  2371.     mov    al,23H            ; desired interrupt vector (^C)
  2372.     mov    ah,getintv        ; Int 21H, function 35H = Get Vector
  2373.     int    dos            ; get vector in es:bx
  2374.     mov    in3ad,bx        ; save offset of original vector
  2375.     mov    in3ad+2,es        ;   and its segment
  2376.     mov    al,24h            ; DOS critical error, Int 24h
  2377.     mov    ah,getintv
  2378.     int    dos
  2379.     mov    word ptr ceadr,bx    ; DOS's Critical Error handler, offset
  2380.     mov    word ptr ceadr+2,es    ;  and segment address
  2381.     push    ds            ; save ds around next DOS calls
  2382.     mov    ax,seg intbrk        ; compose full address of ^C routine
  2383.     mov    ds,ax            ; segment is the code segment
  2384.     mov    dx,offset intbrk    ;   and offset is intbrk
  2385.     mov    al,23H            ; on ^C, goto intbrk
  2386.     mov    ah,setintv        ; set interrupt address from ds:dx
  2387.     int    dos
  2388.     mov    dx,offset dosce        ; replacement Critical Error handler
  2389.     mov    al,24h            ; interrupt 24h
  2390.     mov    ah,setintv        ; replace it
  2391.     int    dos
  2392.     pop    ds
  2393.     mov    ax,3300h        ; get state of Control-Break Check
  2394.     int    dos
  2395.     mov    orgcbrk,dl        ; save state here
  2396.     pop    es
  2397.     ret
  2398. SETINT    ENDP
  2399.  
  2400. ; Control Break, Interrupt 23h replacement
  2401. ; Always return with a Continue (vs Abort) condition since Kermit will cope
  2402. ; with failures. [jrd]
  2403. intbrk:    push ax
  2404.     push    ds    
  2405.     mov    ax,data            ; get Kermit's data segment
  2406.     mov    ds,ax
  2407.     mov    flags.cxzflg,'C'    ; say we saw a ^C
  2408.     mov    rstate,'E'
  2409.     mov    sstate,'E'
  2410.     pop    ds
  2411.     pop    ax
  2412.     iret               ; return to caller in a Continue condition
  2413.  
  2414. ; Kermit's DOS Critical Error Handler, Int 24h. [jrd]
  2415. ; Needed to avoid aborting Kermit with the serial port interrupt active and
  2416. ; the Control Break interrupt redirected. See the DOS Tech Ref Manual for
  2417. ; a start on this material; it is neither complete nor entirely accurate
  2418. ; The stack is the Kermit's stack, the data segment is unknown, interrupts
  2419. ; are off, and the code segment is Kermit's. Note: some implementations of
  2420. ; MS DOS may leave us in DOS's stack. Called by a DOS Int 21h function
  2421. dosce:    test    ah,80h        ; block device (disk drive)?
  2422.     jnz    dosce1        ; nz = no; serial device, memory, etc
  2423.     mov    al,3        ; tell DOS to Fail the Int 21h call
  2424.     iret            ; return to DOS
  2425. dosce1:    add    sp,6        ; pop IP, CS, Flags regs, from DOS's Int 24h
  2426.     pop    ax        ; restore original callers regs existing
  2427.     pop    bx        ;  just before doing Int 21h call
  2428.     pop    cx
  2429.     pop    dx
  2430.     pop    si
  2431.     pop    di
  2432.     pop    bp
  2433.     pop    ds
  2434.     pop    es        
  2435.     mov    al,0ffh        ; signal failure (usually) the DOS 1.x way
  2436.     push    bp        ; Kermit's IP, CS, and Flags are on the stack
  2437.     mov    bp,sp        ;  all ready for an iret, but first a word ..
  2438.     or    word ptr[bp+8],1 ; set carry bit, signals failure DOS 2+ way
  2439.     pop    bp        ; this avoids seeing the Interrupt flag bit
  2440.     iret            ; return to user, simulate return from Int 21h
  2441. code1    ends
  2442.  
  2443. code    segment
  2444.     assume    cs:code
  2445.  
  2446. ; Set DOS' Control-Break Check to off
  2447. cboff    proc    near
  2448.     mov    ax,3301h        ; set Control-Break Chk state
  2449.     xor    dl,dl            ; set state to off
  2450.     int    dos
  2451.     ret
  2452. cboff    endp
  2453.  
  2454. ; Restore DOS's Control-Break Check to startup value
  2455. cbrestore proc    near
  2456.     push    dx
  2457.     mov    ax,3301h        ; set Control-Break Chk state
  2458.     mov    dl,orgcbrk        ; restore state to startup value
  2459.     int    dos
  2460.     pop    dx
  2461.     ret
  2462. cbrestore endp
  2463.  
  2464. ISFILE    PROC    NEAR
  2465. ; Enter with ds:ax pointing at asciiz filename string
  2466. ; Returns carry set if the file pointed to by ax does not exist, else reset
  2467. ; Returns status byte, fstat, with DOS status and high bit set if major error
  2468. ; Does a search-for-first to permit paths and wild cards
  2469. ; Examines All kinds of files (ordinary, subdirs, vol labels, system,
  2470. ;  and hidden). Upgraded to All kinds on 27 Dec 1985. Revised 30 Aug 86 [jrd]
  2471. ; All registers are preserved
  2472.     push    bx
  2473.     push    ax
  2474.     mov    bx,ax
  2475.     mov    ax,[bx]
  2476.     and    ax,not 2020h        ; to upper
  2477.     cmp    ax,'UN'            ; look for DOS 5 NUL
  2478.     jne    isfil4            ; ne = mismatch
  2479.     mov    ax,[bx+2]
  2480.     and    al,not 20h
  2481.     cmp    ax,'L'+0
  2482.     jne    isfil4            ; ne = mismatch
  2483.     pop    ax
  2484.     pop    bx
  2485.     clc                ; say success
  2486.     ret
  2487. isfil4:    pop    ax
  2488.     pop    bx
  2489.     push    dx            ; save regs
  2490.     push    cx
  2491.     push    ax
  2492.     mov    byte ptr filtst.dta+21,0 ; clear old attribute bits
  2493.     mov    byte ptr filtst.fname,0    ; clear any old filenames
  2494.     mov    filtst.fstat,0        ; clear status byte
  2495.     mov     cx,3fH            ; look at all kinds of files
  2496.     mov    dx,offset filtst.dta    ; own own temporary dta
  2497.     mov    ah,setdma        ; set to new dta
  2498.     int    dos
  2499.     pop    dx            ; get ax (filename string ptr)
  2500.     push    dx            ; save it again
  2501.     mov    ah,first2        ; search for first
  2502.     int    dos
  2503.     pushf                ; save flags
  2504.     mov    dx,offset buff        ; reset dma
  2505.     mov    ah,setdma
  2506.     int    dos
  2507.     popf                ; recover flags
  2508.     jnc    isfil1            ; nc = file found
  2509.     mov    filtst.fstat,al        ; record DOS status
  2510.     cmp    al,2            ; just "File Not Found"?
  2511.     je    isfil2            ; e = yes
  2512.     cmp    al,3            ; "Path not found"?
  2513.     je    isfil2            ; e = yes
  2514.     cmp    al,18            ; "No more files"?
  2515.     je    isfil2            ; e = yes
  2516.     or    filtst.fstat,80h    ; set high bit for more serious error
  2517.     jmp    short isfil2    
  2518. isfil1:    cmp    byte ptr filtst.fname,0    ; did DOS fill in a name?
  2519.     je    isfil2            ; z = no
  2520.     clc
  2521.     jmp    short isfil3
  2522. isfil2:    stc                ; else set carry flag bit
  2523. isfil3:    pop    ax
  2524.     pop    cx
  2525.     pop    dx
  2526.     ret                ; DOS sets carry if file not found
  2527. ISFILE    ENDP
  2528.  
  2529. ; initialize memory usage by returning to DOS anything past the end of kermit
  2530. memini    proc    near
  2531.     push    es
  2532.     mov    bx,_TEXT
  2533.     sub    bx,psp
  2534.     mov    totpar,bx        ; save for patcher's magic number
  2535.     mov    es,psp            ; address psp segment again
  2536.     mov    bx,offset msfinal + 15    ; end of pgm + roundup
  2537.     mov    cl,4
  2538.     shr    bx,cl            ; compute # of paragraphs in last seg
  2539.     mov    ax,_STACK        ; last segment
  2540.     sub    ax,psp            ; minus beginning
  2541.     add    bx,ax            ; # of paragraphs occupied
  2542.     mov    ah,setblk
  2543.     int    dos
  2544.     pop    es
  2545.     jnc    memin1
  2546.     mov    dx,offset ermes2
  2547.     mov    ah,prstr
  2548.     int    dos            ; complain
  2549.     jmp    krmend            ; exit Kermit now
  2550. memin1:    pop    dx            ; save return address here
  2551.     mov    ax,_STACK        ; move SS down to DGROUP, adj SP
  2552.     sub    ax,DGROUP        ; paragraphs to move
  2553.     mov    cl,4            ; convert to bytes
  2554.     shl    ax,cl
  2555.     mov    bx,SP            ; current SP offset
  2556.     add    bx,ax            ; new SP, same memory cell
  2557.     mov    ax,bx
  2558.     sub    ax,400            ; top 400 bytes = Kermit
  2559.     mov    tcptos,ax        ; report this as TCP's top of stack
  2560.     mov    ax,DGROUP        ; new SS
  2561.     cli
  2562.     mov    SS,ax
  2563.     mov    SP,bx            ; whew!
  2564.     sti
  2565.     push    dx            ; push return address
  2566.     clc
  2567.     ret
  2568. memini    endp
  2569.  
  2570. ; Allocate memory.  Passed a memory size in ax, allocates that many
  2571. ; bytes (actually rounds up to a paragraph) and returns its SEGMENT in ax
  2572. ; The memory is NOT initialized.  Written by [jrd] to allow memory to
  2573. ; be allocated anywhere in the 1MB address space
  2574. sbrk    proc    near            ; K & R, please forgive us
  2575.     mov    bx,ax            ; bytes wanted
  2576.     add    bx,15            ; round up
  2577.     mov    cl,4
  2578.     shr    bx,cl            ; convert to # of paragraphs
  2579.     mov    cx,bx            ; remember quantity wanted
  2580.     mov    ah,alloc        ; DOS memory allocator
  2581.     int    dos
  2582.     jc    sbrkx            ; c = fatal
  2583.     cmp    cx,bx            ; paragraphs wanted vs delivered
  2584.     jb    sbrkx            ; b = not enough, fatal error
  2585.     ret                ; and return segment in ax
  2586. sbrkx:    mov    dx,offset mfmsg        ; assume not enough memory (ax = 8)
  2587.     cmp    ax,7            ; corrupted memory (ax = 7)?
  2588.     jne    sbrkx1            ; ne = no
  2589.     mov    dx,offset mf7msg    ; corrupted memory found
  2590. sbrkx1:    mov    ah,prstr
  2591.     int    dos
  2592.     jmp    krmend            ; exit Kermit now
  2593. sbrk    endp
  2594. code     ends
  2595.     end    start
  2596.